Add rapids-cython component for scikit-build based Python package builds

RAPIDS.cmake

@@ -21,8 +21,8 @@ set(rapids-cmake-version 22.06)
 include(FetchContent)
 FetchContent_Declare(
   rapids-cmake
-  GIT_REPOSITORY https://github.com/rapidsai/rapids-cmake.git
-  GIT_TAG        branch-${rapids-cmake-version}
+  GIT_REPOSITORY https://github.com/vyasr/rapids-cmake.git
+  GIT_TAG        rapids-cython
 )
 FetchContent_GetProperties(rapids-cmake)
 if(rapids-cmake_POPULATED)

rapids-cmake/cython/create_cython_modules.cmake

@@ -0,0 +1,64 @@
+# =============================================================================
+# Copyright (c) 2022, NVIDIA CORPORATION.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may not use this file except
+# in compliance with the License. You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software distributed under the License
+# is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express
+# or implied. See the License for the specific language governing permissions and limitations under
+# the License.
+# =============================================================================
+
+#[=======================================================================[.rst:
+create_cython_modules
+---------------------
+
+Generate C(++) from Cython and create Python modules.
+
+.. code-block:: cmake
+
+  create_cython_modules(<ModuleName...>)
+
+Creates a Cython target for a module, then adds a corresponding Python
+extension module. This function assumes that we are in a scikit-build managed
+build and that ``find_package(Cython)`` has already been called.
+
+TODO: Is there any way to avoid the above restriction? I don't think we'd want
+to add a find_package call here, but maybe it would be OK and we could use
+rapids_find_package for tracking.
+
+``cython_modules``
+  The list of modules to build.
+
+``linked_libraries``
+  The list of libraries that need to be linked into all modules. In RAPIDS,
+  this list usually contains (at minimum) the corresponding C++ libraries.
+
+``install_base_directory``
+  The source directory of the project. This directory is used to compute the
+  relative install path, which is necessary to propertly support differently
+  configured installations such as installing in place vs. out of place.
+
+#]=======================================================================]
+function(create_cython_modules cython_modules linked_libraries install_base_directory)
+  foreach(cython_module ${cython_modules})
+    add_cython_target(${cython_module} CXX PY3)
+    add_library(${cython_module} MODULE ${cython_module})
+    python_extension_module(${cython_module})
+
+    # To avoid libraries being prefixed with "lib".
+    set_target_properties(${cython_module} PROPERTIES PREFIX "")
+    foreach(lib ${linked_libraries})
+      target_link_libraries(${cython_module} ${lib})
+    endforeach()
+
+    # Compute the install directory relative to the source and rely on installs being relative to
+    # the CMAKE_PREFIX_PATH for e.g. editable installs.
+    cmake_path(RELATIVE_PATH CMAKE_CURRENT_SOURCE_DIR BASE_DIRECTORY ${install_base_directory}
+               OUTPUT_VARIABLE install_dst)
+    install(TARGETS ${cython_module} DESTINATION ${install_dst})
+  endforeach(cython_module ${cython_sources})
+endfunction()

rapids-cmake/cython/skbuild_patches.cmake

@@ -0,0 +1,53 @@
+# =============================================================================
+# Copyright (c) 2022, NVIDIA CORPORATION.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may not use this file except
+# in compliance with the License. You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software distributed under the License
+# is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express
+# or implied. See the License for the specific language governing permissions and limitations under
+# the License.
+# =============================================================================
+
+#[=======================================================================[.rst:
+_set_python_extension_symbol_visibility
+---------------------------------------
+
+The original version of this function in scikit-build runs a linker script to
+modify the visibility of symbols. This version is a patch to avoid overwriting
+the visibility of symbols because otherwise any library that exports symbols
+with external linkage will have the visibility of those symbols changed
+undesirably. We can remove this function once this issue is resolved in
+scikit-build.
+
+Issue: https://github.com/scikit-build/scikit-build/issues/668
+PR: https://github.com/scikit-build/scikit-build/pull/703
+
+#]=======================================================================]
+# TODO: Should we guard this based on a scikit-build version? Override this function to avoid
+# scikit-build clobbering symbol visibility.
+function(_set_python_extension_symbol_visibility _target)
+  if(PYTHON_VERSION_MAJOR VERSION_GREATER 2)
+    set(_modinit_prefix "PyInit_")
+  else()
+    set(_modinit_prefix "init")
+  endif()
+  message("_modinit_prefix:${_modinit_prefix}")
+  if("${CMAKE_C_COMPILER_ID}" STREQUAL "MSVC")
+    set_target_properties(${_target} PROPERTIES LINK_FLAGS "/EXPORT:${_modinit_prefix}${_target}")
+  elseif("${CMAKE_C_COMPILER_ID}" STREQUAL "GNU" AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
+    set(_script_path ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${_target}-version-script.map)
+    file(
+      WRITE ${_script_path}
+      # Note: The change is to this script, which does not indiscriminately mark all non PyInit
+      # symbols as local.
+      "{global: ${_modinit_prefix}${_target}; };")
+    set_property(
+      TARGET ${_target}
+      APPEND_STRING
+      PROPERTY LINK_FLAGS " -Wl,--version-script=\"${_script_path}\"")
+  endif()
+endfunction()

rapids-cmake/rapids-cython.cmake

@@ -0,0 +1,33 @@
+#=============================================================================
+# Copyright (c) 2022, NVIDIA CORPORATION.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#=============================================================================
+include_guard(GLOBAL)
+
+find_package(PythonExtensions REQUIRED)
+find_package(Cython REQUIRED)
+
+# TODO: Verify that the scopes of the below variables (CYTHON_FLAGS,
+# ignored_variable) are suitable for the way that they're being used.
+
+# Set standard Cython directives that all RAPIDS projects should use in compilation.
+set(CYTHON_FLAGS
+    "--directive binding=True,embedsignature=True,always_allow_keywords=True"
+    CACHE STRING "The directives for Cython compilation.")
+
+# Ignore unused variable warning.
+set(ignored_variable "${SKBUILD}" PARENT_SCOPE)
+
+include(${CMAKE_CURRENT_LIST_DIR}/cython/skbuild_patches.cmake)
+include(${CMAKE_CURRENT_LIST_DIR}/cython/create_cython_modules.cmake)