[OpenFX] New Port (#37670)

<!-- If your PR fixes issues, please note that here by adding "Fixes
#NNNNNN." for each fixed issue on separate lines. -->

<!-- If you are still working on the PR, open it as a Draft:
https://github.blog/2019-02-14-introducing-draft-pull-requests/. -->

<!-- If this PR updates an existing port, please uncomment and fill out
this checklist:

- [ ] Changes comply with the [maintainer
guide](https://github.com/microsoft/vcpkg-docs/blob/main/vcpkg/contributing/maintainer-guide.md).
- [ ] SHA512s are updated for each updated download.
- [ ] The "supports" clause reflects platforms that may be fixed by this
new version.
- [ ] Any fixed [CI
baseline](https://github.com/microsoft/vcpkg/blob/master/scripts/ci.baseline.txt)
entries are removed from that file.
- [ ] Any patches that are no longer applied are deleted from the port's
directory.
- [ ] The version database is fixed by rerunning `./vcpkg x-add-version
--all` and committing the result.
- [ ] Only one version is added to each modified port's versions file.

END OF PORT UPDATE CHECKLIST (delete this line) -->

<!-- If this PR adds a new port, please uncomment and fill out this
checklist: -->

- [ ] Changes comply with the [maintainer
guide](https://github.com/microsoft/vcpkg-docs/blob/main/vcpkg/contributing/maintainer-guide.md).
- [x] The name of the port matches an existing name for this component
on https://repology.org/ if possible, and/or is strongly associated with
that component on search engines.
- [x] Optional dependencies are resolved in exactly one way. For
example, if the component is built with CMake, all `find_package` calls
are REQUIRED, are satisfied by `vcpkg.json`'s declared dependencies, or
disabled with
[CMAKE_DISABLE_FIND_PACKAGE_Xxx](https://cmake.org/cmake/help/latest/variable/CMAKE_DISABLE_FIND_PACKAGE_PackageName.html).
- [x] The versioning scheme in `vcpkg.json` matches what upstream says.
- [x] The license declaration in `vcpkg.json` matches what upstream
says.
- [ ] The installed as the "copyright" file matches what upstream says.
- [x] The source code of the component installed comes from an
authoritative source.
- [ ] The generated "usage text" is accurate. See
[adding-usage](https://github.com/microsoft/vcpkg-docs/blob/main/vcpkg/examples/adding-usage.md)
for context.
- [x] The version database is fixed by rerunning `./vcpkg x-add-version
--all` and committing the result.
- [x] Only one version is in the new port's versions file.
- [x] Only one version is added to each modified port's versions file.

<!-- END OF NEW PORT CHECKLIST (delete this line) -->

ports/openfx/CMakeLists.txt

@@ -0,0 +1,73 @@
+cmake_minimum_required(VERSION 3.20)
+
+project(openfx VERSION 1.4.0 LANGUAGES CXX)
+
+set(CMAKE_CXX_STANDARD 14)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+
+if(WIN32)
+    add_compile_definitions(WINDOWS NOMINMAX WIN64)
+    set(OS_VAR "windows")
+    set(OFX_ARCH_NAME "Win64")
+endif()
+
+set(OFX_HEADERS_DIR ${CMAKE_CURRENT_SOURCE_DIR}/include)
+
+add_library(OpenFx INTERFACE)
+target_include_directories(OpenFx
+    INTERFACE
+    $<BUILD_INTERFACE:${OFX_HEADERS_DIR}>
+    $<INSTALL_INTERFACE:include/openfx>
+)
+
+set(OFX_SUPPORT_HEADERS_DIR ${CMAKE_CURRENT_SOURCE_DIR}/Support/include)
+
+add_library(OfxSupport STATIC
+    Support/Library/ofxsCore.cpp
+    Support/Library/ofxsImageEffect.cpp
+    Support/Library/ofxsInteract.cpp
+    Support/Library/ofxsLog.cpp
+    Support/Library/ofxsMultiThread.cpp
+    Support/Library/ofxsParams.cpp
+    Support/Library/ofxsProperty.cpp
+    Support/Library/ofxsPropertyValidation.cpp
+)
+target_include_directories(OfxSupport
+    PUBLIC
+    $<BUILD_INTERFACE:${OFX_HEADERS_DIR}>
+    $<BUILD_INTERFACE:${OFX_SUPPORT_HEADERS_DIR}>
+    $<INSTALL_INTERFACE:include/openfx>
+)
+target_link_libraries(OfxSupport INTERFACE OpenFx)
+target_compile_features(OfxSupport PUBLIC cxx_std_11)
+
+install(
+    TARGETS OpenFx OfxSupport
+    EXPORT openfx-export
+    LIBRARY DESTINATION lib
+    ARCHIVE DESTINATION lib
+)
+
+install(
+    EXPORT openfx-export
+    FILE unofficial-openfxConfig.cmake
+    NAMESPACE unofficial::openfx::
+    DESTINATION "share/unofficial-openfx"
+)
+
+file(GLOB OFX_HEADERS "${OFX_HEADERS_DIR}/*.h" "${OFX_SUPPORT_HEADERS_DIR}/*.h")
+install(FILES ${OFX_HEADERS}
+    DESTINATION include/openfx
+)
+
+include(CMakePackageConfigHelpers)
+
+write_basic_package_version_file(
+    "${CMAKE_CURRENT_BINARY_DIR}/unofficial-openfxConfigVersion.cmake"
+    VERSION ${PROJECT_VERSION}
+    COMPATIBILITY AnyNewerVersion
+)
+install(
+    FILES "${CMAKE_CURRENT_BINARY_DIR}/unofficial-openfxConfigVersion.cmake"
+    DESTINATION "share/unofficial-openfx"
+)

ports/openfx/portfile.cmake

@@ -0,0 +1,22 @@
+string(REPLACE "." "_" UNDERSCORE_VERSION "${VERSION}")
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO AcademySoftwareFoundation/openfx
+    REF "OFX_Release_${UNDERSCORE_VERSION}_TAG"
+    SHA512 b20512ea38823167f191b72f1592548df85fbda6cefe47673972874c139641ee91277e78c1e0d57a457b9f864385e6fa0e4a7edcdbf0c7b2eda956c03a3e1e13
+    HEAD_REF main
+)
+
+file(COPY ${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt DESTINATION ${SOURCE_PATH})
+
+vcpkg_cmake_configure(SOURCE_PATH ${SOURCE_PATH})
+vcpkg_cmake_install()
+vcpkg_fixup_pkgconfig()
+vcpkg_cmake_config_fixup(PACKAGE_NAME unofficial-openfx)
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/include/DocSrc")
+
+configure_file("${CMAKE_CURRENT_LIST_DIR}/usage" "${CURRENT_PACKAGES_DIR}/share/${PORT}/usage" COPYONLY)
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/Support/LICENSE")

ports/openfx/usage

@@ -0,0 +1,7 @@
+The package OpenFX provides CMake targets:
+
+    find_package(unofficial-openfx CONFIG REQUIRED)
+    # C-based API
+    target_link_libraries(main PRIVATE unofficial::openfx::OpenFx)
+    # C++ wrapper
+    target_link_libraries(main PRIVATE unofficial::openfx::OfxSupport)

ports/openfx/vcpkg.json

@@ -0,0 +1,19 @@
+{
+  "$schema": "https://raw.githubusercontent.com/microsoft/vcpkg-tool/main/docs/vcpkg.schema.json",
+  "name": "openfx",
+  "version": "1.4",
+  "maintainers": "Reza Alizadeh Majd <[email protected]>, Behnam Binesh <[email protected]>",
+  "summary": "OpenFX - An open-source plugin API for visual effects",
+  "homepage": "https://github.com/AcademySoftwareFoundation/openfx",
+  "license": "BSD-3-Clause",
+  "dependencies": [
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ]
+}

versions/baseline.json

@@ -6444,6 +6444,10 @@
       "baseline": "2022-07-18",
       "port-version": 0
     },
+    "openfx": {
+      "baseline": "1.4",
+      "port-version": 0
+    },
     "opengl": {
       "baseline": "2022-12-04",
       "port-version": 3

versions/o-/openfx.json

@@ -0,0 +1,9 @@
+{
+  "versions": [
+    {
+      "git-tree": "9bfae0126edf500cbdcb8592715c9bd176b79bfb",
+      "version": "1.4",
+      "port-version": 0
+    }
+  ]
+}