Is there a simple way to move a package from start into opt?

[chrisbra]

Title says it all, I mean I can of course manually move the directory, but it would be great if I could move a package to the opt path, so that it won't get loaded next time I startup Vim.

Thanks for considering.

[k-takata]

If you don't mind losing the commit of the plugin, maybe the easiest way is: change .vimrc to add {'type': 'opt'}, source it, then call minpac#update() and minpac#clean().

Another idea is...
A user can get the directory of the plugin by minpac#getpluginfo('plugin_name').dir. So a user might be able to define a custom command using it and rename() to move the plugin.
I'm not sure whether minpac should have this feature by default.

[chrisbra]

hm, it is not so easy. I tried with this approach:

    command! -nargs=1 -complete=customlist,CompletePack PackDisable
            \ let url=minpac#getpluginfo(<q-args>).url |
            \ call minpac#clean(<q-args>) |
            \ call minpac#add(url, {'type': 'opt'}) |
            \ call minpac#update()
    command! PackUpdate packadd minpac | source $MYVIMRC | call minpac#update()
    command! PackClean  packadd minpac | source $MYVIMRC | call minpac#clean()
    func! CompletePack(A, Cmd, Pos)
    return map(glob("~/.vim/pack/minpac/start/". a:A. "*", 0, 1), 'substitute(v:val, ".*/", "", "g")')
    endfunc

That works, however I still have to change the minpac#add() call...

[k-takata]

A user can get the directory of the plugin by minpac#getpluginfo('plugin_name').dir. So a user might be able to define a custom command using it and rename() to move the plugin.

Here is a snippet based on this idea:

let plugdir = minpac#getpluginfo(plugin_name).dir
call rename(plugdir, substitute(plugdir, '/start/\ze[^/]\+$', '/opt/', ''))

That works, however I still have to change the minpac#add() call...

Yes..., users should always update minpac#add() properly.

[chrisbra]

That should be put into the documentation ;)

[k-takata]

Updated example:

command! -nargs=1 -complete=customlist,CompletePack PackDisable
        \ let plugdir=minpac#getpluginfo(<q-args>).dir |
        \ call rename(plugdir, substitute(plugdir, '/start/\ze[^/]\+$', '/opt/', ''))
func! CompletePack(A, Cmd, Pos)
        return minpac#getpackages('minpac', 'start', a:A . '*', 1)
endfunc

[k-takata]

Fixed by #46.

[chrisbra]

how does #46 fix it? I looked at the PR (only briefly), but don't know how this solves this problem.

[k-takata]

Edit your .vimrc and add {'type': 'opt'} to the plugin you want to move from 'start' to 'opt', then execute minpac#update(). The plugin directory will be automatically moved under the 'opt' directory.

however I still have to change the minpac#add() call...

This is still not changed, but I think this is the expected behavior.

[chrisbra]

ah thanks!

[mralusw]

So it's still not entirely clear, can I move stuff from opt/ to start/ manually and vice versa? Can I zip the pack/minpac folder and move it to another machine?

[k-takata]

As I wrote above, if you want to move a plugin from opt/ to start/, edit your .vimrc and remove {'type': 'opt'} from the plugin setting, then execute minpac#update().

Can I zip the pack/minpac folder and move it to another machine?

It doesn't seem to related this, but yes, you can.

[mralusw]

Thanks. I don't actually configure plugins (other than minpac#init) in my .vimrc at all, I just use minpac#add to install, then :packadd to load them from vim when needed. Maybe this should be a separate issue though.

[k-takata]

If you have a line call minpac#add('user/plugin') in your .vimrc, the plugin will be installed into the start/ directory.
If you change the line to call minpac#add('user/plugin', {'type': 'opt'}), then execute minpac#update(), the directory will be moved into the opt/ directory.