How to order objects of multi-links returned in subshapes

[mabagoury]

In my schema, I have a Question, Answer, and Comment object types. A question can have multiple answers and comments. An answer can have multiple comments.
I need to return all fields of the question including its comments, answers, and answer comments ordered by some property like creation date.
I understand how to order the result set of the outer shape, but I can't find a workaround to order the results of the subshapes.
The query currently looks like:

select Question {
  id,
  title,
  content,
  date_created,

  answers: {
    id,
    content,
    date_created,
    comments: {
      id,
      content,
      date_created,
    }
  },

  comments: {
    id,
    content,
    date_created,
  }
}
filter .id = <uuid>$question_id

I want to order the results of each multi-link by their creation date while returning them in a subshape.

[tailhook]

It works by desugaring link name into a full-blown select:

select Question {
  id,
  title,
  comments := (
    SELECT .comments {
      id,
      content,
      date_created,
    }
    ORDER BY .date_created
  )
}
filter .id = <uuid>$question_id

[elprans]

Explicit desugaring is usually not necessary, you can also stick filter and order by after the subshape:

select Question {
  id,
  title,
  comments: {
    id,
    content,
    date_created,
  } order by .date_created
}
filter .id = <uuid>$question_id

[mabagoury]

Wow. I though subqueries are not allowed in select queries as the fields are already well defined.
This saved my day. Thanks for the help and for this great product.

[mabagoury]

But what happens if the subquery returns a set that violate some constraints defined in the schema or return a set of object of a different type than the on defined for the propert in the schema?
I mean, in the examples I found in the docs, those computed properties always had different names than the ones defined in the schema.
And in my question, I compute a property that is defined in the schema with a type and some constraints.
Let's say, the subquery returns some answers instead of some comments.
Let's say this subquery:

  comments := (
    SELECT .comments {
      id,
      content,
      date_created,
    }

is changed to:

  comments := (
    SELECT .answers {
      id,
      content,
      date_created,
    }

Now, is the property comments now considered a "free" property different than the type Question comments property?
Or some checks are tested against the property declaration and an error is thrown?

[tailhook]

You can't change type or cardinality of the field in shape. So filtering, sorting, limiting multi links and multi properties is okay. For other expressions it's better to have a different name.

Although, "constraints" are checked only on write operations (insert/update).

[mabagoury]

I see. Thanks for the explanation.