Add tests for local function exceptions in cppia

test/cppia/Client.hx

@@ -159,6 +159,26 @@ class Client
          return;
       }
 
+      switch LocalFunctionExceptions.testLocalCallingStatic() {
+         case Error(message):
+            Common.status = 'Failed test for throw in static called by local: ' + message;
+            return;
+         default:
+      }
+
+      switch LocalFunctionExceptions.testCatchWithinLocal() {
+         case Error(message):
+            Common.status = 'Failed test for catch in local function: ' + message;
+            return;
+         default:
+      }
+
+      switch LocalFunctionExceptions.testCatchFromLocal() {
+         case Error(message):
+            Common.status = 'Failed test for catching exception from local function: ' + message;
+            return;
+         default:
+      }
 
       final extending = new ClientExtendedExtendedRoot();
 

test/cppia/LocalFunctionExceptions.hx

@@ -0,0 +1,68 @@
+enum Status {
+	Ok;
+	Error(message:String);
+}
+
+class LocalFunctionExceptions {
+	static function staticFunction() {
+		throw 'Thrown from static';
+	}
+
+	public static function testLocalCallingStatic():Status {
+		function localFunction() {
+			staticFunction();
+			throw 'Thrown from local';
+		}
+
+		try {
+			localFunction();
+		} catch (e:String) {
+			if (e == 'Thrown from static') {
+				return Ok;
+			} else {
+				return Error("Incorrect exception caught from local function call");
+			}
+		}
+
+		return Error("No exception caught");
+	}
+
+	public static function testCatchWithinLocal():Status {
+		function localFunction() {
+			try {
+				staticFunction();
+			} catch (e:String) {
+				if (e == 'Thrown from static') {
+					return Ok;
+				} else {
+					return Error("Incorrect exception caught from local function call");
+				}
+			}
+			return Error("Exception from static function not caught");
+		}
+
+		return try {
+			localFunction();
+		} catch (e) {
+			Error('Exception leaked from local function: $e');
+		};
+	}
+
+	public static function testCatchFromLocal():Status {
+		function localFunction() {
+			throw 'Thrown from local';
+		}
+
+		try {
+			localFunction();
+		} catch (e:String) {
+			if (e == 'Thrown from local') {
+				return Ok;
+			} else {
+				return Error("Incorrect exception caught from local function call");
+			}
+		}
+
+		return Error("No exception caught");
+	}
+}