Pratt parsing and explicit node elision

[0x2a-42]

Fix for #2.

Node elision for rules is now an explicit operation and no longer determined by certain rule patterns. Left recursive rules are now parsed by a Pratt parser.

Migration Guide

The empty node rename operator @ is no longer allowed. It was previously used to avoid matching certain rule patterns, which is no longer necessary.

Operator Precedence

Use the node elision operator for the non-recursive branches.

Before

bin_expr:
  bin_expr ('*' | '/') bin_expr
| bin_expr ('+' | '-') bin_expr
| primary_expr
;

After

bin_expr:
  bin_expr ('*' | '/') bin_expr
| bin_expr ('+' | '-') bin_expr
| primary_expr ^
;

Unconditional Forwarding

Add the elision operator after the rule name.

Before

stmt:
  for_stmt
| while_stmt
| expr_stmt
| return_stmt
;

After

stmt^:
  for_stmt
| while_stmt
| expr_stmt
| return_stmt
;

Conditional Forwarding

Add the elision operator after the rule name and create a node explicitly.

Before

assign_expr: bin_expr ['=' assign_expr];

After

assign_expr^: bin_expr ['=' assign_expr >];

Right Recursive Forwarding

Use the node elision operator for the non-recursive branches.

Before

unary_expr:
  ('+' | '-') unary_expr
| primary_expr
;

After

unary_expr:
  ('+' | '-') unary_expr
| primary_expr ^
;

Maybe Empty

Add the elision operator after the rule name and create a node explicitly.

Before

generic_args:
  ['<' type_list '>']
;

After

generic_args^:
  ['<' type_list '>' >]
;