MIES_Publish.ipf: Add TESTPULSE_SET_VALUE_FILTER

Send a message when changing a TP setting in the DAEphys panel.

Author: t-b

Packages/MIES/MIES_Constants.ipf

@@ -1887,6 +1887,7 @@ StrConstant PRESSURE_STATE_FILTER             = "pressure:state"
 StrConstant PRESSURE_SEALED_FILTER            = "pressure:sealed"
 StrConstant PRESSURE_BREAKIN_FILTER           = "pressure:break in"
 StrConstant AUTO_TP_FILTER                    = "testpulse:autotune result"
+StrConstant TESTPULSE_SET_VALUE_FILTER        = "testpulse:set value"
 StrConstant ZMQ_FILTER_TPRESULT_NOW           = "testpulse:results live"
 StrConstant ZMQ_FILTER_TPRESULT_1S            = "testpulse:results 1s update"
 StrConstant ZMQ_FILTER_TPRESULT_5S            = "testpulse:results 5s update"

Packages/MIES/MIES_DAEphys.ipf

@@ -5513,11 +5513,47 @@ static Function/S DAP_TPControlToLabel(string ctrl)
 	endswitch
 End
 
+/// @brief Get the physical unit for the control name
+static Function/S DAP_TPControlToUnit(string ctrl)
+
+	strswitch(ctrl)
+		case "SetVar_DataAcq_TPDuration":
+			return "ms"
+		case "SetVar_DataAcq_TPBaselinePerc":
+			return "%"
+		case "SetVar_DataAcq_TPAmplitude":
+			return "pA"
+		case "SetVar_DataAcq_TPAmplitudeIC":
+			return "mV"
+		case "setvar_Settings_TPBuffer":
+			return "a.u."
+		case "setvar_Settings_TP_RTolerance":
+			return "MΩ"
+		case "check_DataAcq_AutoTP":
+			return "On/Off"
+		case "setvar_DataAcq_IinjMax":
+			return "pA"
+		case "setvar_DataAcq_targetVoltage":
+			return "mV"
+		case "setvar_DataAcq_targetVoltageRange":
+			return "mV"
+		case "Check_TP_SendToAllHS":
+			return "On/Off"
+		case "setvar_Settings_autoTP_perc":
+			return "%"
+		case "setvar_Settings_autoTP_int":
+			return "s"
+		default:
+			ASSERT(0, "invalid control")
+			break
+	endswitch
+End
+
 /// @brief Write a new TP setting value to the wave
 static Function DAP_TPGUISettingToWave(string device, string ctrl, variable val)
 
-	string lbl, entry
-	variable first, last, TPState, needsTPRestart
+	string lbl, entry, unit
+	variable first, last, TPState, needsTPRestart, headstage, i
 
 	needsTPRestart = WhichListItem(ctrl, DAEPHYS_TP_CONTROLS_NO_RESTART) == -1
 
@@ -5546,6 +5582,12 @@ static Function DAP_TPGUISettingToWave(string device, string ctrl, variable val)
 
 	TPSettings[%$lbl][first, last] = val
 
+	unit = DAP_TPControlToUnit(ctrl)
+	for(i = first; i <= last; i += 1)
+		headstage = IsValidHeadstage(i) ? i : NaN
+		PUB_TPSettingChange(device, headstage, lbl, val, unit)
+	endfor
+
 	if(!cmpstr(lbl, "autoTPEnable"))
 		TP_AutoTPGenerateNewCycleID(device, first = first, last = last)
 		DAP_AdaptAutoTPColorAndDependent(device)

Packages/MIES/MIES_ForeignFunctionInterface.ipf

@@ -86,6 +86,7 @@ End
 ///  :cpp:var:ZMQ_FILTER_TPRESULT_NOW_WITH_DATA   TP evaluation result with AD data (all TPs)          :cpp:func:PUB_TPResult
 ///  :cpp:var:CONFIG_FINISHED_FILTER              JSON configuration for panel has finished            :cpp:func:PUB_ConfigurationFinished
 ///  :cpp:var:AMPLIFIER_SET_VALUE                 Amplifier setting was changed through MIES           :cpp:func:PUB_AmplifierSettingChange
+///  :cpp:var:TESTPULSE_SET_VALUE_FILTER          Testpulse setting change                             :cpp:func:PUB_TPSettingChange
 /// ============================================ ==================================================== =============================================
 ///
 /// \endrst
@@ -98,7 +99,7 @@ Function/WAVE FFI_GetAvailableMessageFilters()
 	                  ANALYSIS_FUNCTION_VM, DAQ_TP_STATE_CHANGE_FILTER,                                   \
 	                  ANALYSIS_FUNCTION_AR, ZMQ_FILTER_TPRESULT_NOW, ZMQ_FILTER_TPRESULT_1S,              \
 	                  ZMQ_FILTER_TPRESULT_5S, ZMQ_FILTER_TPRESULT_10S, ZMQ_FILTER_TPRESULT_NOW_WITH_DATA, \
-	                  CONFIG_FINISHED_FILTER, AMPLIFIER_SET_VALUE}
+	                  CONFIG_FINISHED_FILTER, AMPLIFIER_SET_VALUE, TESTPULSE_SET_VALUE_FILTER}
 
 	Note/K wv, "Heartbeat is sent every 5 seconds."
 

Packages/MIES/MIES_Publish.ipf

@@ -989,3 +989,18 @@ Function PUB_AmplifierSettingChange(string device, variable headstage, variable
 
 	PUB_Publish(jsonID, AMPLIFIER_SET_VALUE)
 End
+
+Function PUB_TPSettingChange(string device, variable headstage, string name, variable value, string unit)
+
+	variable jsonID
+	string   path
+
+	jsonID = PUB_GetJSONTemplate(device, headstage)
+
+	path = "/testpulse setting"
+	JSON_AddTreeObject(jsonID, path)
+
+	PUB_AddValueWithUnit(jsonID, path + "/" + name, value, unit)
+
+	PUB_Publish(jsonID, TESTPULSE_SET_VALUE_FILTER)
+End

Packages/tests/Basic/UTF_ZeroMQPublishing.ipf

@@ -711,3 +711,65 @@ static Function CheckAmplifierSettingChange()
 
 	JSON_Release(jsonID)
 End
+
+/// Filter: #TESTPULSE_SET_VALUE_FILTER
+///
+/// Example:
+///
+/// \rst
+/// .. code-block:: json
+///
+///    {
+///      "device": "my_device",
+///      "headstage": 1,
+///      "sweep number": "NaN",
+///      "testpulse setting": {
+///        "my name": {
+///          "unit": "On/Off",
+///          "value": 1
+///        }
+///      },
+///      "timestamp": "2025-04-25T20:26:44Z"
+///    }
+///
+/// \endrst
+static Function CheckTestpulseSettingChange()
+
+	string device, name, unit, actual, expected, path
+	variable value, headstage, jsonID, valActual, valExpected
+
+	device    = "my_device"
+	headstage = 1
+	name      = "my name"
+	unit      = "On/Off"
+	value     = 1
+
+	PUB_TPSettingChange(device, headstage, name, value, unit)
+
+	jsonID = FetchAndParseMessage(TESTPULSE_SET_VALUE_FILTER)
+
+	actual   = JSON_GetString(jsonID, "/device")
+	expected = device
+	CHECK_EQUAL_STR(actual, expected)
+
+	valActual   = JSON_GetVariable(jsonID, "/headstage")
+	valExpected = headstage
+	CHECK_EQUAL_VAR(valActual, valExpected)
+
+	path        = "/testpulse setting/" + name
+	valActual   = JSON_GetType(jsonID, path)
+	valExpected = JSON_OBJECT
+	CHECK_EQUAL_VAR(valActual, valExpected)
+
+	CHECK_EQUAL_STR(actual, expected)
+
+	valActual   = JSON_GetVariable(jsonID, path + "/value")
+	valExpected = value
+	CHECK_EQUAL_VAR(valActual, valExpected)
+
+	actual   = JSON_GetString(jsonID, path + "/unit")
+	expected = unit
+	CHECK_EQUAL_STR(actual, expected)
+
+	JSON_Release(jsonID)
+End

Packages/tests/HardwareBasic/UTF_TestPulseAndTPDuringDAQ.ipf

@@ -125,7 +125,20 @@ End
 
 static Function CheckTPEntriesFromLBN_PreAcq(string device)
 
+	variable jsonID
+	string   path
+
+	PrepareForPublishTest()
+
 	PGC_SetAndActivateControl(device, "setvar_Settings_TP_RTolerance", val = 2)
+
+	jsonID = FetchAndParseMessage(TESTPULSE_SET_VALUE_FILTER)
+	CHECK_EQUAL_VAR(JSON_GetVariable(jsonID, "/headstage"), NaN)
+	path = "/testpulse setting/resistanceTol"
+	CHECK_EQUAL_STR(JSON_GetString(jsonID, path + "/unit"), "MΩ")
+	CHECK_EQUAL_VAR(JSON_GetVariable(jsonID, path + "/value"), 2)
+	JSON_Release(jsonID)
+
 	PGC_SetAndActivateControl(device, "setvar_Settings_TPBuffer", val = 3)
 
 	// turn off send to all HS

Packages/tests/UTF_HelperFunctions.ipf

@@ -13,7 +13,7 @@
 #include "UTF_Constants"
 #include "UTF_DataGenerators"
 
-// #define OUTPUT_DOCUMENTATION_JSON_DUMP
+#define OUTPUT_DOCUMENTATION_JSON_DUMP
 
 /// @file UTF_HelperFunctions.ipf
 /// @brief This file holds helper functions for the tests