MIES_Publish.ipf: Add AMPLIFIER_SET_VALUE

t-b · t-b · commit 2f8fddd12c8e · 2025-03-25T17:08:20.000+01:00
diff --git a/Packages/MIES/MIES_AmplifierInteraction.ipf b/Packages/MIES/MIES_AmplifierInteraction.ipf
@@ -1574,7 +1574,7 @@ End
 static Function AI_SendToAmp(string device, variable headStage, variable mode, variable func, variable accessType, [variable checkBeforeWrite, variable usePrefixes, variable selectAmp, variable value])
 
 	variable ret, headstageMode, scale
-	string str
+	string str, name
 
 	ASSERT(func > MCC_BEGIN_INVALID_FUNC && func < MCC_END_INVALID_FUNC, "MCC function constant is out for range")
 	ASSERT(IsValidHeadstage(headstage), "invalid headStage index")
@@ -1657,6 +1657,11 @@ static Function AI_SendToAmp(string device, variable headStage, variable mode, v
 			endif
 	endswitch
 
+	if(accessType == MCC_WRITE)
+		name = AI_MapFunctionConstantToName(func, mode)
+		PUB_AmplifierSettingChange(device, headstage, mode, name, value)
+	endif
+
 	if(!IsFinite(ret))
 		print "Amp communication error. Check associations in hardware tab and/or use Query connected amps button"
 		ControlWindowToFront()
diff --git a/Packages/MIES/MIES_Constants.ipf b/Packages/MIES/MIES_Constants.ipf
@@ -1863,6 +1863,7 @@ StrConstant ZMQ_FILTER_TPRESULT_10S           = "testpulse:results 10s update"
 StrConstant ZMQ_FILTER_TPRESULT_NOW_WITH_DATA = "testpulse:results live with data"
 StrConstant AMPLIFIER_CLAMP_MODE_FILTER       = "amplifier:clamp mode"
 StrConstant AMPLIFIER_AUTO_BRIDGE_BALANCE     = "amplifier:auto bridge balance"
+StrConstant AMPLIFIER_SET_VALUE               = "amplifier:set value"
 StrConstant ANALYSIS_FUNCTION_PB              = "analysis function:pipette in bath"
 StrConstant ANALYSIS_FUNCTION_SE              = "analysis function:seal evaluation"
 StrConstant ANALYSIS_FUNCTION_VM              = "analysis function:true resting membrane potential"
diff --git a/Packages/MIES/MIES_ForeignFunctionInterface.ipf b/Packages/MIES/MIES_ForeignFunctionInterface.ipf
@@ -85,6 +85,7 @@ End
 ///  :cpp:var:ZMQ_FILTER_TPRESULT_10s             TP evaluation result (every 10s)                     :cpp:func:PUB_TPResult
 ///  :cpp:var:ZMQ_FILTER_TPRESULT_NOW_WITH_DATA   TP evaluation result with AD data (all TPs)          :cpp:func:PUB_TPResult
 ///  :cpp:var:CONFIG_FINISHED_FILTER              JSON configuration for panel has finished            :cpp:func:PUB_ConfigurationFinished
+///  :cpp:var:AMPLIFIER_SET_VALUE                 Amplifier setting was changed through MIES           :cpp:func:PUB_AmplifierSettingChange
 /// ============================================ ==================================================== =============================================
 ///
 /// \endrst
@@ -97,7 +98,7 @@ Function/WAVE FFI_GetAvailableMessageFilters()
 	                  ANALYSIS_FUNCTION_VM, DAQ_TP_STATE_CHANGE_FILTER,                                   \
 	                  ANALYSIS_FUNCTION_AR, ZMQ_FILTER_TPRESULT_NOW, ZMQ_FILTER_TPRESULT_1S,              \
 	                  ZMQ_FILTER_TPRESULT_5S, ZMQ_FILTER_TPRESULT_10S, ZMQ_FILTER_TPRESULT_NOW_WITH_DATA, \
-	                  CONFIG_FINISHED_FILTER}
+	                  CONFIG_FINISHED_FILTER, AMPLIFIER_SET_VALUE}
 
 	Note/K wv, "Heartbeat is sent every 5 seconds."
 
diff --git a/Packages/MIES/MIES_Publish.ipf b/Packages/MIES/MIES_Publish.ipf
@@ -946,3 +946,39 @@ Function PUB_ConfigurationFinished(string windowName, string panelType, string f
 
 	PUB_Publish(jsonID, CONFIG_FINISHED_FILTER)
 End
+
+/// Filter: #AMPLIFIER_SET_VALUE
+///
+/// The available names are listed in AI_MapFunctionConstantToName().
+///
+/// Example:
+///
+/// \rst
+/// .. code-block:: json
+///
+///    {
+///      "amplifier action": {
+///        "name": "some entry",
+///        "value": 123
+///      },
+///      "clamp mode": "V_CLAMP_MODE",
+///      "device": "my_device",
+///      "headstage": 1,
+///      "sweep number": "NaN",
+///      "timestamp": "2025-02-25T20:30:24Z"
+///    }
+///
+/// \endrst
+Function PUB_AmplifierSettingChange(string device, variable headstage, variable mode, string name, variable value)
+
+	variable jsonID
+
+	jsonID = PUB_GetJSONTemplate(device, headstage)
+
+	JSON_AddString(jsonID, "clamp mode", ConvertAmplifierModeToString(mode))
+	JSON_AddTreeObject(jsonID, "/amplifier action")
+	JSON_AddString(jsonID, "/amplifier action/name", name)
+	JSON_AddVariable(jsonID, "/amplifier action/value", value)
+
+	PUB_Publish(jsonID, AMPLIFIER_SET_VALUE)
+End
diff --git a/Packages/tests/Basic/UTF_ZeroMQPublishing.ipf b/Packages/tests/Basic/UTF_ZeroMQPublishing.ipf
@@ -659,3 +659,41 @@ static Function CheckConfigurationFinished()
 
 	JSON_Release(jsonID)
 End
+
+static Function CheckAmplifierSettingChange()
+
+	string device, actual, expected, name
+	variable jsonID, valActual, valExpected, headstage, mode, value
+
+	device    = "my_device"
+	headstage = 1
+	mode      = V_CLAMP_MODE
+	name      = "some entry"
+	value     = 123
+
+	PUB_AmplifierSettingChange(device, headstage, mode, name, value)
+
+	jsonID = FetchAndParseMessage(AMPLIFIER_SET_VALUE)
+
+	actual   = JSON_GetString(jsonID, "/device")
+	expected = device
+	CHECK_EQUAL_STR(actual, expected)
+
+	valActual   = JSON_GetVariable(jsonID, "/headstage")
+	valExpected = headstage
+	CHECK_EQUAL_VAR(valActual, valExpected)
+
+	actual   = JSON_GetString(jsonID, "/clamp mode")
+	expected = ConvertAmplifierModeToString(mode)
+	CHECK_EQUAL_STR(actual, expected)
+
+	actual   = JSON_GetString(jsonID, "/amplifier action/name")
+	expected = name
+	CHECK_EQUAL_STR(actual, expected)
+
+	valActual   = JSON_GetVariable(jsonID, "/amplifier action/value")
+	valExpected = value
+	CHECK_EQUAL_VAR(valActual, valExpected)
+
+	JSON_Release(jsonID)
+End
diff --git a/Packages/tests/HardwareBasic/UTF_ConfigurationHardware.ipf b/Packages/tests/HardwareBasic/UTF_ConfigurationHardware.ipf
@@ -103,6 +103,8 @@ static Function CheckIfConfigurationRestoresMCCFilterGain([string str])
 	string rewrittenConfig, fName
 	variable val, gain, filterFreq, headStage, jsonID
 
+	PrepareForPublishTest()
+
 	fName = PrependExperimentFolder_IGNORE("CheckIfConfigurationRestoresMCCFilterGain.json")
 
 	STRUCT DAQSettings s
@@ -119,6 +121,12 @@ static Function CheckIfConfigurationRestoresMCCFilterGain([string str])
 	AI_WriteToAmplifier(str, headStage + 1, I_CLAMP_MODE, MCC_PRIMARYSIGNALLPF_FUNC, filterFreq)
 	AI_WriteToAmplifier(str, headStage + 1, I_CLAMP_MODE, MCC_PRIMARYSIGNALGAIN_FUNC, gain)
 
+	jsonID = FetchAndParseMessage(AMPLIFIER_SET_VALUE)
+	CHECK_EQUAL_VAR(JSON_GetVariable(jsonID, "/headstage"), headStage)
+	CHECK_EQUAL_STR(JSON_GetString(jsonID, "/amplifier action/name"), "SetPrimarySignalLPF")
+	CHECK_EQUAL_VAR(JSON_GetVariable(jsonID, "/amplifier action/value"), filterFreq)
+	JSON_Release(jsonID)
+
 	PGC_SetAndActivateControl(str, "check_Settings_SyncMiesToMCC", val = 1)
 
 	CONF_SaveWindow(fName)
