MIES_Publish.ipf: Add AMPLIFIER_SET_VALUE

Author: t-b

Packages/MIES/MIES_AmplifierInteraction.ipf

@@ -1745,6 +1745,10 @@ static Function AI_SendToAmp(string device, variable headStage, variable mode, v
 			endif
 	endswitch
 
+	if(accessType == MCC_WRITE)
+		PUB_AmplifierSettingChange(device, headstage, mode, func, value)
+	endif
+
 	if(!IsFinite(ret))
 		print "Amp communication error. Check associations in hardware tab and/or use Query connected amps button"
 		ControlWindowToFront()

Packages/MIES/MIES_Constants.ipf

@@ -1864,6 +1864,7 @@ StrConstant ZMQ_FILTER_TPRESULT_10S           = "testpulse:results 10s update"
 StrConstant ZMQ_FILTER_TPRESULT_NOW_WITH_DATA = "testpulse:results live with data"
 StrConstant AMPLIFIER_CLAMP_MODE_FILTER       = "amplifier:clamp mode"
 StrConstant AMPLIFIER_AUTO_BRIDGE_BALANCE     = "amplifier:auto bridge balance"
+StrConstant AMPLIFIER_SET_VALUE               = "amplifier:set value"
 StrConstant ANALYSIS_FUNCTION_PB              = "analysis function:pipette in bath"
 StrConstant ANALYSIS_FUNCTION_SE              = "analysis function:seal evaluation"
 StrConstant ANALYSIS_FUNCTION_VM              = "analysis function:true resting membrane potential"

Packages/MIES/MIES_ForeignFunctionInterface.ipf

@@ -85,6 +85,7 @@ End
 ///  :cpp:var:ZMQ_FILTER_TPRESULT_10s             TP evaluation result (every 10s)                     :cpp:func:PUB_TPResult
 ///  :cpp:var:ZMQ_FILTER_TPRESULT_NOW_WITH_DATA   TP evaluation result with AD data (all TPs)          :cpp:func:PUB_TPResult
 ///  :cpp:var:CONFIG_FINISHED_FILTER              JSON configuration for panel has finished            :cpp:func:PUB_ConfigurationFinished
+///  :cpp:var:AMPLIFIER_SET_VALUE                 Amplifier setting was changed through MIES           :cpp:func:PUB_AmplifierSettingChange
 /// ============================================ ==================================================== =============================================
 ///
 /// \endrst
@@ -97,7 +98,7 @@ Function/WAVE FFI_GetAvailableMessageFilters()
 	                  ANALYSIS_FUNCTION_VM, DAQ_TP_STATE_CHANGE_FILTER,                                   \
 	                  ANALYSIS_FUNCTION_AR, ZMQ_FILTER_TPRESULT_NOW, ZMQ_FILTER_TPRESULT_1S,              \
 	                  ZMQ_FILTER_TPRESULT_5S, ZMQ_FILTER_TPRESULT_10S, ZMQ_FILTER_TPRESULT_NOW_WITH_DATA, \
-	                  CONFIG_FINISHED_FILTER}
+	                  CONFIG_FINISHED_FILTER, AMPLIFIER_SET_VALUE}
 
 	Note/K wv, "Heartbeat is sent every 5 seconds."
 

Packages/MIES/MIES_Publish.ipf

@@ -946,3 +946,46 @@ Function PUB_ConfigurationFinished(string windowName, string panelType, string f
 
 	PUB_Publish(jsonID, CONFIG_FINISHED_FILTER)
 End
+
+/// Filter: #AMPLIFIER_SET_VALUE
+///
+/// The available names are listed in AI_MapFunctionConstantToName().
+///
+/// Example:
+///
+/// \rst
+/// .. code-block:: json
+///
+///    {
+///      "amplifier action": {
+///        "HoldingPotentialEnable": {
+///          "unit": "On/Off",
+///          "value": 1
+///        }
+///      },
+///      "clamp mode": "V_CLAMP_MODE",
+///      "device": "my_device",
+///      "headstage": 1,
+///      "sweep number": "NaN",
+///      "timestamp": "2025-03-25T16:42:21Z"
+///    }
+///
+/// \endrst
+Function PUB_AmplifierSettingChange(string device, variable headstage, variable mode, variable func, variable value)
+
+	variable jsonID
+	string path, unit, name
+
+	jsonID = PUB_GetJSONTemplate(device, headstage)
+
+	JSON_AddString(jsonID, "clamp mode", ConvertAmplifierModeToString(mode))
+
+	path = "/amplifier action"
+	JSON_AddTreeObject(jsonID, path)
+
+	unit = AI_GetUnitForFunctionConstant(func, mode)
+	name = AI_MapFunctionConstantToName(func, mode)
+	PUB_AddValueWithUnit(jsonID, path + "/" + name, value, unit)
+
+	PUB_Publish(jsonID, AMPLIFIER_SET_VALUE)
+End

Packages/tests/Basic/UTF_ZeroMQPublishing.ipf

@@ -664,3 +664,50 @@ static Function CheckConfigurationFinished()
 
 	JSON_Release(jsonID)
 End
+
+static Function CheckAmplifierSettingChange()
+
+	string device, actual, expected, name, unit, path
+	variable jsonID, valActual, valExpected, headstage, mode, value, func
+
+	device    = "my_device"
+	headstage = 1
+	mode      = V_CLAMP_MODE
+	func      = MCC_HOLDINGENABLE_FUNC
+	name      = "HoldingPotentialEnable"
+	unit      = "On/Off"
+	value     = 1
+
+	PUB_AmplifierSettingChange(device, headstage, mode, func, value)
+
+	jsonID = FetchAndParseMessage(AMPLIFIER_SET_VALUE)
+
+	actual   = JSON_GetString(jsonID, "/device")
+	expected = device
+	CHECK_EQUAL_STR(actual, expected)
+
+	valActual   = JSON_GetVariable(jsonID, "/headstage")
+	valExpected = headstage
+	CHECK_EQUAL_VAR(valActual, valExpected)
+
+	actual   = JSON_GetString(jsonID, "/clamp mode")
+	expected = ConvertAmplifierModeToString(mode)
+	CHECK_EQUAL_STR(actual, expected)
+
+	path        = "/amplifier action/" + name
+	valActual   = JSON_GetType(jsonID, path)
+	valExpected = JSON_OBJECT
+	CHECK_EQUAL_VAR(valActual, valExpected)
+
+	CHECK_EQUAL_STR(actual, expected)
+
+	valActual   = JSON_GetVariable(jsonID, path + "/value")
+	valExpected = value
+	CHECK_EQUAL_VAR(valActual, valExpected)
+
+	actual   = JSON_GetString(jsonID, path + "/unit")
+	expected = unit
+	CHECK_EQUAL_STR(actual, expected)
+
+	JSON_Release(jsonID)
+End

Packages/tests/HardwareBasic/UTF_ConfigurationHardware.ipf

@@ -100,9 +100,11 @@ End
 // UTF_TD_GENERATOR DeviceNameGeneratorMD1
 static Function CheckIfConfigurationRestoresMCCFilterGain([string str])
 
-	string rewrittenConfig, fName
+	string rewrittenConfig, fName, path
 	variable val, gain, filterFreq, headStage, jsonID
 
+	PrepareForPublishTest()
+
 	fName = PrependExperimentFolder_IGNORE("CheckIfConfigurationRestoresMCCFilterGain.json")
 
 	STRUCT DAQSettings s
@@ -119,6 +121,13 @@ static Function CheckIfConfigurationRestoresMCCFilterGain([string str])
 	AI_WriteToAmplifier(str, headStage + 1, I_CLAMP_MODE, MCC_PRIMARYSIGNALLPF_FUNC, filterFreq)
 	AI_WriteToAmplifier(str, headStage + 1, I_CLAMP_MODE, MCC_PRIMARYSIGNALGAIN_FUNC, gain)
 
+	jsonID = FetchAndParseMessage(AMPLIFIER_SET_VALUE)
+	CHECK_EQUAL_VAR(JSON_GetVariable(jsonID, "/headstage"), headStage)
+	path = "/amplifier action/SetPrimarySignalLPF"
+	CHECK_EQUAL_STR(JSON_GetString(jsonID, path + "/unit"), "kHz")
+	CHECK_EQUAL_VAR(JSON_GetVariable(jsonID, path + "/value"), filterFreq)
+	JSON_Release(jsonID)
+
 	PGC_SetAndActivateControl(str, "check_Settings_SyncMiesToMCC", val = 1)
 
 	CONF_SaveWindow(fName)