build.gradle

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
            jcenter()
        }
    }
    dependencies {
        classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.3"
        classpath "com.marklogic:ml-gradle:3.2.0"
    }
}

plugins {
    id "com.marklogic.ml-gradle" version "3.3.0"
}

mlPostDeploy.dependsOn ":mlJobRepo:deployMarkLogicJobRepository"
mlUndeploy.dependsOn "mlJobRepo:undeployMarkLogicJobRepository"

allprojects {
    apply plugin: "checkstyle"
    apply plugin: "pmd"

    repositories {
        jcenter()
        mavenCentral()
        maven { url "http://repo.spring.io/release" }
        maven { url "http://developer.marklogic.com/maven2/" }
    }

    task wrapper(type: Wrapper) {
        gradleVersion = '4.4.1'
    }

    pmd {
        ruleSets = ["java-basic", "java-braces", "java-unusedcode"]
    }

    checkstyle {
        configFile = file("${project.rootDir}/config/checkstyle/checkstyle.xml")
        toolVersion = '7.1.2'
    }

}

subprojects {

    apply plugin: "java"
    apply plugin: "maven-publish"
    apply plugin: "idea"

    ext {
        springBatchVersion = '4.0.0.RELEASE'
        springVersion = '5.0.2.RELEASE'
    }

    dependencies {
        compile "org.slf4j:slf4j-api:1.7.25"
        compile "org.slf4j:slf4j-log4j12:1.7.25"
        compile "org.apache.logging.log4j:log4j-api:2.9.1"

        testCompile "junit:junit:4.12"
    }

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    task cleanJavaDocs(type: Delete) {
        delete fileTree("../sastafford.github.io/marklogic-spring-batch/javadoc")
    }

    javadoc.dependsOn cleanJavaDocs
}