Trac #29361: openblas spkg-configure.m4: Fix the check for lapack/cblas functions

This line (introduced in #29071):
{{{
        AC_FC_FREEFORM([AC_FC_FUNC([dgeqrf])])
}}}
is not executed at all because `AC_FC_FREEFORM` is `AC_DEFUN_ONCE` and
is called already in `gfortran/spkg-configure.m4`

As a result:
{{{
Checking whether SageMath should install SPKG openblas...
checking BLAS library... openblas
checking whether any of gfortran is installed or will be installed as
SPKG... no
checking for openblas >= 0.2.20... yes
checking for cblas_dgemm... yes
checking for ... no
checking for lapack... no
configure: no suitable system package found for SPKG openblas
}}}

In this ticket, we fix the check by avoiding `AC_FC_FUNC` altogether,
which is not suitable to be used in a configure that must work if no
Fortran compiler is available.

(Factored out from #29104.)

URL: https://trac.sagemath.org/29361
Reported by: mkoeppe
Ticket author(s): Matthias Koeppe
Reviewer(s): Dima Pasechnik

Author: Release Manager

build/pkgs/openblas/spkg-configure.m4

@@ -1,25 +1,37 @@
 SAGE_SPKG_CONFIGURE([openblas], [
  SAGE_SPKG_DEPCHECK([gfortran], [
   PKG_CHECK_MODULES([OPENBLAS], [openblas >= 0.2.20], [
+    SAVE_LIBS="$LIBS"
+    LIBS="$OPENBLAS_LIBS $LIBS"
+    SAVE_CFLAGS="$CFLAGS"
+    CFLAGS="$OPENBLAS_CFLAGS $CFLAGS"
     PKG_CHECK_VAR([OPENBLASPCDIR], [openblas], [pcfiledir], [
        sage_install_blas_pc=yes
-       AC_SEARCH_LIBS([cblas_dgemm], [openblas], [dnl openblas works as cblas
+       AC_CHECK_FUNC([cblas_dgemm], [dnl openblas works as cblas
              sage_install_cblas_pc=yes
              ], [
-             dnl openblas does not work as cblas; try to use system's cblas as is
+             dnl openblas does not work as cblas; try to use system cblas as is
              PKG_CHECK_MODULES([CBLAS], [cblas], [], [sage_spkg_install_openblas=yes])
           ])
-       AC_FC_FREEFORM([AC_FC_FUNC([dgeqrf])])
-       AC_SEARCH_LIBS([$dgeqrf], [openblas], [dnl openblas works as lapack
+       dnl Check all name manglings that AC_FC_FUNC could check based on the
+       dnl characteristics of the Fortran compiler
+       m4_foreach([dgeqrf_mangled], [dgeqrf, dgeqrf_, DGEQRF, DGEQRF_], [
+          AC_CHECK_FUNC(dgeqrf_mangled, [
+             AS_VAR_SET([HAVE_DGEQRF], [yes])
+          ])
+       ])
+       AS_IF([test x$HAVE_DGEQRF = xyes], [dnl openblas works as lapack
              sage_install_lapack_pc=yes
              ], [
-             dnl openblas does not work as lapack; try to use system's lapack as is
+             dnl openblas does not work as lapack; try to use system lapack as is
              PKG_CHECK_MODULES([LAPACK], [lapack], [], [sage_spkg_install_openblas=yes])
           ])
        ], [
        AC_MSG_WARN([Unable to locate the directory of openblas.pc. This should not happen!])
        sage_spkg_install_openblas=yes
        ])
+    LIBS="$SAVE_LIBS"
+    CFLAGS="$SAVE_CFLAGS"
     ], [sage_spkg_install_openblas=yes])
     AS_IF([test x$sage_spkg_install_openblas != xyes], [
        m4_foreach([blaslibnam], [blas, cblas, lapack], [