build.gradle

plugins {
    id 'java'
    id 'idea'
    id 'com.github.johnrengelman.shadow' version '7.0.0'
}

group 'cn.apisium.nekopanel'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
    maven {
        name = 'papermc'
        url = 'https://papermc.io/repo/repository/maven-public/'
    }
    maven {
        name = 'sonatype'
        url = 'https://oss.sonatype.org/content/groups/public/'
    }
    maven {
        name = 'jitpack'
        url = 'https://jitpack.io'
    }
}

dependencies {
    compileOnly 'org.spigotmc:plugin-annotations:1.2.3-SNAPSHOT'
    compileOnly 'io.papermc.paper:paper-api:1.17-R0.1-SNAPSHOT'
    compileOnly 'com.github.Apisium:NekoEssentials:360360dc11'
    compileOnly 'com.github.Apisium:Uniporter:1.2.6-SNAPSHOT'
    compileOnly 'io.netty:netty-all:4.1.65.Final'

    implementation 'com.github.Apisium:netty-engine.io:03931aef8c'
    implementation ('io.socket:engine.io-server:5.0.0') {
        exclude group: 'com.google.code.gson'
    }
    implementation ('io.socket:socket.io-server:3.0.1') {
        exclude group: 'org.json'
        exclude group: 'com.squareup.okhttp3'
        exclude group: 'io.socket', module: 'engine.io-server'
        exclude group: 'io.socket', module: 'engine.io-client'
    }

    annotationProcessor 'org.spigotmc:plugin-annotations:1.2.3-SNAPSHOT'
}

shadowJar {
    dependencies {
        relocate('org.json', 'cn.apisium.nekomaid.libs.org.json')
        relocate('javax.servlet', 'cn.apisium.nekomaid.libs.javax.servlet')
        relocate('io.socket', 'cn.apisium.nekomaid.libs.io.socket')
    }

    archiveClassifier.set('')
    minimize()
}
build.dependsOn(shadowJar)