build.gradle

/*
 *  Copyright 2018-present the original author or authors.
 *
 *  Licensed under the Apache License, Version 2.0 (the "License");
 *  you may not use this file except in compliance with the License.
 *  You may obtain a copy of the License at
 *
 *        http://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing, software
 *  distributed under the License is distributed on an "AS IS" BASIS,
 *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 *  See the License for the specific language governing permissions and
 *  limitations under the License.
 */

buildscript {
  ext {
  }

  repositories {
    gradlePluginPortal()
    mavenCentral()
    jcenter()
  }

  dependencies {
    classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
  }
}

// *********************************************************************************************************************
// Enable plugins
// *********************************************************************************************************************
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'java'
// Apply Boot plugin to provide managed, blessed dependencies and Gradle tasks such as assembling fat executable jar
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'

// *********************************************************************************************************************
// Project Properties
// *********************************************************************************************************************
// Standard project properties. These are used as default values by some assembly and release task, e.g. jar
// See gradle.properties and settings.gradle, e.g.
//project.name - Property defined in settings.gradle, overriding default used by Gradle which is based on project dir
//project.version - Property defined in gradle.properties

// Extra user-defined project properties
ext {
  // Cribbed from https://github.com/mindscratch/reactor-offline/blob/master/build.gradle
  javadocLinks = [
    "http://docs.oracle.com/javase/8/docs/api/"
  ] as String[]
}

repositories {
  jcenter()
  mavenCentral()
}

dependencies {
  // Compile-time dependencies
  compile("org.springframework.boot:spring-boot-starter-web")
  compile("com.amazonaws.serverless:aws-serverless-java-container-spring:[${awsServerlessJavaContainerSpringMinVersion},)")
  compile("io.symphonia:lambda-logging:${symphoniaLambdaLoggingVersion}")

  // Test dependencies
  testCompile("org.junit.jupiter:junit-jupiter-api:${junitJupiterVersion}")
  // Workaround for JUnit 5 bug. Suppress warnings output on compiling test classes reporting that classes (enums) that
  // JUnit 5 depends upon can't be found. See https://github.com/junit-team/junit5/issues/1065
  testCompileOnly("org.apiguardian:apiguardian-api:${apiguardianApiVersion}")
  testCompile("org.assertj:assertj-core:${assertjVersion}")
  testCompile('org.springframework.boot:spring-boot-starter-test')
  testRuntime("org.junit.jupiter:junit-jupiter-engine:${junitJupiterVersion}")
}

// *********************************************************************************************************************
// Task configuration
// *********************************************************************************************************************

bootRun {
  // Propagate any Java system properties specified on launching Gradle that are used by this task. This is necessary
  // as the app is run in a different JVM/java process to Gradle
  systemProperties = (Map) System.properties.subMap(
    "spring.profiles.active"
  )
}

eclipse {
  classpath {
    downloadJavadoc = true  // defaults to 'false'
  }
}

idea {
  project {
    // Using Java 8, as that's the latest version currently  supported by the AWS Lambda service
    jdkName = '8'
    languageLevel = '8'
  }
}

test {
  useJUnitPlatform() // Enable support for JUnit 5+

  testLogging {
    showStandardStreams = true // Log any output that the tests write to stdout or stderr
    events "passed", "skipped", "failed" // Log the execution of each test and its result
  }
}

// *********************************************************************************************************************
// Tasks
// *********************************************************************************************************************

/**
 * Custom task for running javadoc on Java classes in src/test/java
 */
task javadocTests(type: Javadoc, group: "documentation" ) {
  source = sourceSets.test.allJava
  classpath = configurations.testCompile
  options.links(project.ext.javadocLinks)
  options.addBooleanOption('html5',true)
}

/**
 * Packages this AWS serverless Java container app and its dependencies into an artefact of the same type and format 
 * required for deploying functions to AWS Lambda.  
 * <p>
 * AWS Lambda requires a function (and hence this serverless Java container app)  to be packaged as a zip file that 
 * has a Lambda specific dir structure layout (similar to a WAR). For more details see the AWS Lambda Dev Guide > 
 * Building Lambda Functions with Java > AWS Lambda Deployment Package in Java.
 */
task packageForAwsLambda(type: Zip) {
  classifier = 'lambda-package'
  // Add Java classes
  from compileJava
  // Add resources in src/main/resources
  from processResources
  // Add dependent libs, required at runtime
  into('lib') {
    from(configurations.runtimeClasspath) {
      // Exclude embedded Tomcat libs provided by Spring Boot. The AWS serverless Java container lib provides Jetty.
      exclude 'tomcat-embed-*'
    }
  }
}

assemble.dependsOn packageForAwsLambda