build.gradle

apply plugin: 'com.android.library'
apply plugin: 'android-maven'

android {
    compileSdkVersion 19
    buildToolsVersion "22.0.1"

    defaultConfig {
        minSdkVersion 15
        targetSdkVersion 22
        versionCode 1
        versionName "1.1"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    
    // multiple flavours. produces the following artifacts: -productionRelease.aar, -sandboxRelease.aar, -productionDebug.aar, -sandboxDebug.aar
    productFlavors {
        production {
            buildConfigField 'String', 'ENV', '"PRODUCTION"'
        }
        sandbox {
            buildConfigField 'String', 'ENV', '"SANDBOX"'
        }
    }
    
    // default build flavour
    defaultPublishConfig "productionRelease"
    // true to publish all flavour artifacts
    publishNonDefault true
}

// Publish default flavour as main artifact, otherwise the maven pom is not generated
if( android.productFlavors.size() > 0 ) {
    android.libraryVariants.all { variant ->
        if( android.publishNonDefault && variant.name == android.defaultPublishConfig ) {
            def bundleTask = tasks["bundle${name.capitalize()}"]
            artifacts {
                archives(bundleTask.archivePath) {
                    classifier null
                    builtBy bundleTask
                }
            }
        }
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
}