-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathscheme.S
1793 lines (1685 loc) · 26.4 KB
/
scheme.S
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#### A simple Scheme interpreter
#### With a SICP-esque Cheney's algorithm garbage collector
#### Copyright (c) 2024 Jeandre Kruger
#### All rights reserved.
#### Redistribution and use in source and binary forms, with or without
#### modification, are permitted provided that the following conditions
#### are met:
#### 1. Redistributions of source code must retain the above copyright
#### notice, this list of conditions and the following disclaimer.
#### 2. Redistributions in binary form must reproduce the above copyright
#### notice, this list of conditions and the following disclaimer in the
#### documentation and/or other materials provided with the distribution.
#### THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
#### ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
#### LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
#### PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE FOUNDATION OR
#### CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
#### EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
#### PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
#### PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
#### LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
#### NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
#### SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
### (Strings are allocated using malloc and swept by GC, possibly
### not ideal)
#include "scheme.h"
#define REG_FROMSPACE $s5
#define REG_TOSPACE $s6
#define REG_FREE $s7
#define PAIR_MEM pair_memory
#define SPACE_SIZE 0x10000
#define SYMBOL_LENGTH 16
#define BROKEN_HEART 4
#define TRUE 7
#define FALSE 3
#define NUM_PRIMITIVES 28
# Every stack frame reachable by GC must have no dead values.
#define ZEROFRAME \
sw $zero,8($sp); \
sw $zero,4($sp); \
sw $zero,($sp)
#define SYM(name) sym_ ## name
#define NAME_SYM(n1, n2) .align 4; sym_ ## n1 = . + 3; .string n2
#define MAKE_SYM(name) .align 4; .string name
.globl scheme_main
scheme_main:
la $t0,gc_top_of_stack
sw $sp,($t0)
la REG_TOSPACE,PAIR_MEM
la REG_FROMSPACE,PAIR_MEM + SPACE_SIZE
move REG_FREE,REG_TOSPACE
addi $sp,$sp,-16
ZEROFRAME
sw $ra,12($sp)
la $t0,error_sp
sw $sp,($t0)
la $t0,error_pc
la $t1,Lprompt
sw $t1,($t0)
la $a0,str_msg
jal writestr
la $a0,image_env
lw $a0,($a0)
beqz $a0,Lnot_imaged
la $t0,image_free
lw REG_FREE,($t0)
j Lready
Lnot_imaged:
la $a0,str_fresh
jal writestr
jal make_initial_environment
sw $v0,8($sp)
move $a0,$v0
jal add_prims_platform_dependent
lw $a1,8($sp)
la $t0,global_env
sw $a1,($t0) # For LOAD
la $a0,boot_scm_path
jal load # XXX error handling
lw $a0,8($sp)
Lready:
sw $a0,8($sp) # Saved for reason of error
Lprompt:
li $a0,'>'
jal writechar
li $a0,0
jal read
move $a0,$v0
lw $a1,8($sp)
jal eval
la $t0,SYM(ok)
beq $v0,$t0,Lprompt
move $a0,$v0
jal write
li $a0,'\n'
jal writechar
j Lprompt
.globl error
error:
sw $a1,12($sp)
jal writestr
lw $a0,12($sp)
beqz $a0,2f
jal write
2:
li $a0,'\n'
jal writechar
la $t0,error_sp
lw $sp,($t0)
la $t0,error_pc
lw $t0,($t0)
jr $t0
.globl load
load:
addi $sp,$sp,-16
sw $ra,12($sp)
sw $zero,($sp)
sw $a1,4($sp)
jal open_input_file
sw $v0,8($sp)
move $a0,$v0
1:
jal read
la $t0,SYM(Eof)
beq $v0,$t0,2f
move $a0,$v0
lw $a1,4($sp)
jal eval
lw $a0,8($sp)
j 1b
2:
lw $a0,8($sp)
jal close_input_file
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
### Initial environment and primitives
.globl make_initial_environment
make_initial_environment:
addi $sp,$sp,-16
sw $ra,12($sp)
sw $s1,8($sp)
sw $s2,4($sp)
sw $s3,($sp)
la $s1,SYM(ok) + SYMBOL_LENGTH
li $s2,NUM_PRIMITIVES
li $a1,0
1:
beqz $s2,2f
move $a0,$s1
jal cons
move $a1,$v0
addi $s1,$s1,SYMBOL_LENGTH
addi $s2,$s2,-1
j 1b
2:
move $s3,$a1
la $s1,prim_addrs
li $s2,NUM_PRIMITIVES
li $a1,0
1:
beqz $s2,2f
lw $a0,($s1)
ori $a0,$a0,TAG_PROCEDURE
jal cons
move $a1,$v0
addi $s1,$s1,4
addi $s2,$s2,-1
j 1b
2:
move $a0,$s3
jal cons
move $a0,$v0
li $a1,0
jal cons
lw $s3,($sp)
lw $s2,4($sp)
lw $s1,8($sp)
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
.align 3
prim_eq:
DYADIC_ARGS
Lcmp:
bne $a0,$a1,1f
li $v0,TRUE
jr $ra
1:
li $v0,FALSE
jr $ra
.align 3
prim_integerp:
lw $a0,($a0)
andi $a0,$a0,7
li $t0,TAG_FIXNUM
bne $a0,$t0,1f
li $v0,TRUE
jr $ra
1:
li $v0,FALSE
jr $ra
.align 3
prim_num_eql:
DYADIC_ARGS
CHECK_FIXNUM($a0)
CHECK_FIXNUM($a1)
j Lcmp
.align 3
prim_lt:
DYADIC_ARGS
CHECK_FIXNUM($a0)
CHECK_FIXNUM($a1)
slt $v0,$a0,$a1
sll $v0,$v0,3
addi $v0,$v0,FALSE
jr $ra
.align 3
prim_add:
DYADIC_ARGS
CHECK_FIXNUM($a0)
CHECK_FIXNUM($a1)
xori $a1,$a1,TAG_FIXNUM
add $v0,$a0,$a1
jr $ra
.align 3
prim_sub:
DYADIC_ARGS
CHECK_FIXNUM($a0)
CHECK_FIXNUM($a1)
xori $a1,$a1,TAG_FIXNUM
sub $v0,$a0,$a1
jr $ra
.align 3
prim_mul:
DYADIC_ARGS
CHECK_FIXNUM($a0)
CHECK_FIXNUM($a1)
xori $a0,$a0,TAG_FIXNUM
sra $a1,$a1,3
mul $v0,$a0,$a1
ori $v0,$v0,TAG_FIXNUM
jr $ra
.align 3
prim_quotient:
DYADIC_ARGS
CHECK_FIXNUM($a0)
CHECK_FIXNUM($a1)
sra $a0,$a0,3
sra $a1,$a1,3
div $v0,$a0,$a1
sll $v0,$v0,3
ori $v0,$v0,TAG_FIXNUM
jr $ra
.align 3
prim_remainder:
DYADIC_ARGS
CHECK_FIXNUM($a0)
CHECK_FIXNUM($a1)
sra $a0,$a0,3
sra $a1,$a1,3
rem $v0,$a0,$a1
sll $v0,$v0,3
ori $v0,$v0,TAG_FIXNUM
jr $ra
.align 3
prim_modulo:
DYADIC_ARGS
CHECK_FIXNUM($a0)
CHECK_FIXNUM($a1)
sra $a0,$a0,3
sra $a1,$a1,3
## Could this be simpler?
rem $v0,$a0,$a1
bge $v0,$zero,1f
blt $a1,$zero,2f
add $v0,$v0,$a1
1:
bge $a1,$zero,2f
add $v0,$v0,$a1
2:
sll $v0,$v0,3
ori $v0,$v0,TAG_FIXNUM
jr $ra
.align 3
prim_pairp:
lw $a0,($a0)
andi $t0,$a0,7
bnez $t0,1f
beqz $a0,1f
li $v0,TRUE
jr $ra
1:
li $v0,FALSE
jr $ra
.align 3
prim_cons:
lw $t0,4($a0)
lw $t0,($t0)
sw $t0,4($a0)
move $v0,$a0
jr $ra
.align 3
prim_car:
lw $a0,($a0)
CHECK_PAIR($a0)
lw $v0,($a0)
jr $ra
.align 3
prim_cdr:
lw $a0,($a0)
CHECK_PAIR($a0)
lw $v0,4($a0)
jr $ra
.align 3
prim_set_car:
DYADIC_ARGS
CHECK_PAIR($a0)
sw $a1,($a0)
la $v0,SYM(ok)
jr $ra
.align 3
prim_set_cdr:
DYADIC_ARGS
CHECK_PAIR($a0)
sw $a1,4($a0)
la $v0,SYM(ok)
jr $ra
.align 3
prim_list:
move $v0,$a0
jr $ra
.align 3
prim_symbolp:
lw $a0,($a0)
andi $t0,$a0,7
li $t1,TAG_SYMBOL
bne $t0,$t1,1f
li $t0,TRUE
beq $a0,$t0,1f
li $t0,FALSE
beq $a0,$t0,1f
li $v0,TRUE
jr $ra
1:
li $v0,FALSE
jr $ra
.align 3
prim_symbol2string:
lw $a0,($a0)
andi $t0,$a0,7
li $t1,TAG_SYMBOL
bne $t0,$t1,1f
li $t0,TRUE
beq $a0,$t0,1f
li $t0,FALSE
beq $a0,$t0,1f
j 2f
1:
move $a1,$a0
la $a0,str_type_symbol
j error
2:
xori $a1,$a0,TAG_SYMBOL
move $t0,$a1
li $a0,0
3:
lb $t1,($t0)
beqz $t1,4f
addi $t0,$t0,1
addi $a0,$a0,1
j 3b
4:
j alloc_string
## Note: R5RS does not explicitly list the EOF object as a disjoint type
## set, therefore we can have STRING->SYMBOL as long as slashification
## does not exist.
.align 3
prim_string2symbol:
lw $a0,($a0)
CHECK_STRING($a0)
xori $a0,$a0,TAG_STRING
addi $a0,$a0,5
j intern
.align 3
prim_stringp:
lw $a0,($a0)
andi $t0,$a0,7
li $t1,TAG_STRING
bne $t0,$t1,1f
li $v0,TRUE
jr $ra
1:
li $v0,FALSE
jr $ra
.align 3
prim_string_length:
lw $a0,($a0)
CHECK_STRING($a0)
xori $a0,$a0,TAG_STRING
addi $a0,$a0,5
li $v0,0
1:
lb $t0,($a0)
beqz $t0,2f
addi $a0,$a0,1
addi $v0,$v0,1
j 1b
2:
sll $v0,$v0,3
ori $v0,$v0,TAG_FIXNUM
jr $ra
.align 3
prim_procedurep:
lw $a0,($a0)
andi $t0,$a0,7
li $t1,TAG_PROCEDURE
bne $t0,$t1,1f
li $v0,TRUE
jr $ra
1:
li $v0,FALSE
jr $ra
.align 3
prim_read:
li $a0,0
j read
.align 3
prim_write:
lw $a0,($a0)
addi $sp,$sp,-16
sw $ra,12($sp)
jal write
la $v0,SYM(ok)
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
.align 3
prim_display:
lw $a0,($a0)
addi $sp,$sp,-16
sw $ra,12($sp)
li $t0,1
la $t1,printer_display_flag
sw $t0,($t1)
jal write
la $t1,printer_display_flag
sw $zero,($t1)
la $v0,SYM(ok)
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
.align 3
prim_newline:
addi $sp,$sp,-16
sw $ra,12($sp)
li $a0,'\n'
jal writechar
la $v0,SYM(ok)
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
.align 3
prim_image:
addi $sp,$sp,-16
sw $ra,12($sp)
ZEROFRAME
jal gc
blt REG_TOSPACE,REG_FROMSPACE,1f
jal gc
1:
li $t0,PAIR_MEM - 16
lw $t0,8($t0)
la $t1,image_env
sw $t0,($t1)
la $t1,image_free
sw REG_FREE,($t1)
li $a0,0
li $a1,PAIR_MEM + SPACE_SIZE
## XXX
#jal image
la $v0,SYM(ok)
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
.align 3
prim_load:
lw $a0,($a0)
CHECK_STRING($a0)
addi $sp,$sp,-16
sw $ra,12($sp)
ZEROFRAME
xori $a0,$a0,TAG_STRING
addi $a0,$a0,5
la $a1,global_env
lw $a1,($a1)
jal load
la $v0,SYM(ok)
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
### Evaluator
.globl eval
eval:
andi $t0,$a0,7
bnez $t0,1f
beqz $a0,2f
j Leval_pair
1:
li $t1,TAG_FIXNUM
beq $t0,$t1,Leval_self_evaluating
li $t1,TAG_SYMBOL
bne $t0,$t1,2f
li $t0,FALSE
beq $a0,$t0,Leval_self_evaluating
j Leval_variable
2:
li $t1,TAG_STRING
beq $t0,$t1,Leval_self_evaluating
li $t0,TRUE
beq $a0,$t0,Leval_self_evaluating
move $a1,$a0
la $a0,str_bad_exp
j error
Leval_self_evaluating:
move $v0,$a0
jr $ra
Leval_variable:
j lookup
Leval_pair:
lw $t0,($a0)
la $t1,SYM(quote)
beq $t0,$t1,Leval_quote
la $t1,SYM(lambda)
beq $t0,$t1,Leval_lambda
la $t1,SYM(if)
beq $t0,$t1,Leval_if
la $t1,SYM(set)
beq $t0,$t1,Leval_set
la $t1,SYM(begin)
beq $t0,$t1,Leval_begin
la $t1,SYM(cond)
beq $t0,$t1,Leval_cond
la $t1,SYM(let)
beq $t0,$t1,Leval_let
la $t1,SYM(define)
beq $t0,$t1,Leval_define
addi $sp,$sp,-16
sw $zero,($sp)
sw $ra,12($sp)
lw $a0,4($a0)
sw $a1,8($sp)
sw $t0,4($sp)
jal eval_arguments
sw $v0,($sp)
lw $a0,4($sp)
lw $a1,8($sp)
jal eval
lw $a1,($sp)
lw $ra,12($sp)
addi $sp,$sp,16
move $a0,$v0
j apply
## Special forms
Leval_quote:
lw $a0,4($a0)
lw $v0,($a0)
jr $ra
Leval_lambda:
lw $t0,4($a0)
lw $a0,($t0)
move $a2,$a1
lw $a1,4($t0)
j make_procedure
Leval_if:
addi $sp,$sp,-16
sw $ra,12($sp)
ZEROFRAME
lw $t0,4($a0)
lw $a0,($t0)
lw $t0,4($t0)
sw $t0,8($sp)
sw $a1,4($sp)
jal eval
lw $a1,4($sp)
lw $t0,8($sp)
li $t1,FALSE
beq $v0,$t1,Leval_alt
j Leval_conseq
Leval_alt:
lw $t0,4($t0)
bnez $t0,Leval_conseq
la $v0,SYM(ok)
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
Leval_conseq:
lw $a0,($t0)
lw $ra,12($sp)
addi $sp,$sp,16
j eval
Leval_set:
addi $sp,$sp,-16
sw $ra,12($sp)
sw $s1,8($sp)
sw $s2,4($sp)
sw $zero,($sp)
lw $a0,4($a0)
lw $s1,($a0)
lw $a0,4($a0)
lw $a0,($a0)
move $s2,$a1
jal eval
move $a1,$v0
move $a0,$s1
move $a2,$s2
lw $s2,4($sp)
lw $s1,8($sp)
lw $ra,12($sp)
addi $sp,$sp,16
j set_variable
Leval_begin:
lw $a0,4($a0)
j eval_sequence
Leval_cond:
addi $sp,$sp,-16
sw $ra,12($sp)
sw $s1,8($sp)
sw $s2,4($sp)
sw $s3,($sp)
lw $s1,4($a0)
move $s2,$a1
1:
bnez $s1,2f
la $v0,SYM(ok)
lw $s3,($sp)
lw $s2,4($sp)
lw $s1,8($sp)
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
2:
lw $t0,($s1)
lw $a0,($t0)
lw $s3,4($t0)
move $a1,$s2
jal eval
li $t0,FALSE
beq $v0,$t0,3f
move $a0,$s3
move $a1,$s2
lw $s3,($sp)
lw $s2,4($sp)
lw $s1,8($sp)
lw $ra,12($sp)
addi $sp,$sp,16
j eval_sequence
3:
lw $s1,4($s1)
j 1b
Leval_let:
# $s1 = let bindings
# $s2 = let body
# $s3 = variables
# $s4 = values
# $s5 = expression
# $s6 = environment
addi $sp,$sp,-32
sw $ra,28($sp)
sw $s1,24($sp)
sw $s2,20($sp)
sw $s3,16($sp)
sw $s4,12($sp)
sw $s5,8($sp)
sw $s6,4($sp)
sw $zero,($sp)
lw $t0,4($a0)
lw $s1,($t0)
lw $s2,4($t0)
li $s3,0
li $s4,0
move $s6,$a1
1:
beqz $s1,2f
lw $t0,($s1)
lw $s5,4($t0)
lw $s5,($s5)
lw $a0,($t0)
move $a1,$s3
jal cons
move $s3,$a0
move $a0,$s5
move $a1,$s6
jal eval
move $a1,$s4
jal cons
move $s4,$a0
lw $s1,4($s1)
j 1b
2:
move $a0,$s3
move $a1,$s4
jal cons
move $a1,$s6
jal cons
move $a1,$a0
move $a0,$s2
lw $s6,4($sp)
lw $s5,8($sp)
lw $s4,12($sp)
lw $s3,16($sp)
lw $s2,20($sp)
lw $s1,24($sp)
lw $ra,28($sp)
addi $sp,$sp,32
j eval_sequence
Leval_define:
addi $sp,$sp,-16
sw $ra,12($sp)
ZEROFRAME
sw $a1,8($sp)
lw $t0,4($a0)
lw $t1,($t0)
andi $t2,$t1,7
bnez $t2,1f
lw $t2,($t1)
lw $a0,4($t1)
lw $a1,4($t0)
sw $t2,4($sp)
jal cons
move $a1,$v0
la $a0,SYM(lambda)
jal cons
move $a0,$v0 # check this
j 2f
1:
lw $t0,4($t0)
lw $a0,($t0)
sw $t1,4($sp)
2:
lw $a1,8($sp)
jal eval
move $a1,$v0
lw $a0,4($sp)
lw $a2,8($sp)
lw $ra,12($sp)
addi $sp,$sp,16
j define_variable
eval_arguments:
addi $sp,$sp,-16
sw $ra,12($sp)
move $t0,$a0
li $t1,0
1:
beqz $t0,2f
sw $t0,8($sp)
sw $t1,4($sp)
sw $a1,($sp)
lw $a0,($t0)
jal eval
move $a0,$v0
lw $a1,4($sp)
jal cons
move $t1,$v0
lw $t0,8($sp)
lw $t0,4($t0)
lw $a1,($sp)
j 1b
2:
move $a0,$t1
lw $ra,12($sp)
addi $sp,$sp,16
j nreverse
eval_sequence:
move $t0,$a0
lw $a0,($t0)
lw $t0,4($t0)
beqz $t0,eval
addi $sp,$sp,-16
sw $ra,12($sp)
sw $zero,($sp)
j 2f
1:
lw $a0,($t0)
lw $t0,4($t0)
beqz $t0,3f
2:
sw $t0,8($sp)
sw $a1,4($sp)
jal eval
lw $a1,4($sp)
lw $t0,8($sp)
j 1b
3:
lw $ra,12($sp)
addi $sp,$sp,16
j eval
### Procedures and environments
.globl make_procedure
make_procedure:
addi $sp,$sp,-16
ZEROFRAME
sw $ra,12($sp)
sw $s1,8($sp)
move $s1,$a2
jal cons
move $a1,$v0
move $a0,$s1
jal cons
ori $v0,$v0,TAG_PROCEDURE
lw $s1,8($sp)
lw $ra,12($sp)
addi $sp,$sp,16
jr $ra
.globl apply
apply:
andi $t0,$a0,7
li $t1,TAG_PROCEDURE
bne $t0,$t1,Lnot_proc
xori $t0,$a0,TAG_PROCEDURE
la $t1,PAIR_MEM
blt $t0,$t1,Lapply_primitive
la $t1,PAIR_MEM + 2*SPACE_SIZE
bgt $t0,$t1,Lapply_primitive
addi $sp,$sp,-16
ZEROFRAME
sw $ra,12($sp)
sw $t0,8($sp)
lw $t0,4($t0)
lw $a0,($t0)
jal cons
move $a0,$v0
lw $t0,8($sp)
lw $a1,($t0)
jal cons
move $a1,$v0
lw $t0,8($sp)
lw $t0,4($t0)
lw $a0,4($t0)
lw $ra,12($sp)
addi $sp,$sp,16
j eval_sequence
Lapply_primitive:
move $a0,$a1
jr $t0
Lnot_proc:
move $a1,$a0
la $a0,str_not_proc
j error
.globl lookup
lookup:
beqz $a1,Lunbound
lw $t1,($a1)
lw $t2,($t1)
lw $t3,4($t1)
1:
beqz $t2,3f
lw $t4,($t2)
beq $t4,$a0,2f
lw $t2,4($t2)
lw $t3,4($t3)
j 1b
2:
lw $v0,($t3)
jr $ra
3:
lw $a1,4($a1)
j lookup
.globl set_variable
set_variable:
beqz $a2,Lunbound
lw $t1,($a2)
lw $t2,($t1)
lw $t3,4($t1)
1:
beqz $t2,3f
lw $t4,($t2)
beq $t4,$a0,2f
lw $t2,4($t2)
lw $t3,4($t3)
j 1b
2:
sw $a1,($t3)
la $v0,SYM(ok)
jr $ra
3:
lw $a2,4($a2)
j set_variable
Lunbound:
move $a1,$a0
la $a0,str_unbound
j error
.globl define_variable
define_variable:
lw $t0,($a2)
lw $t1,($t0)
lw $t2,4($t0)
1:
beqz $t1,3f
lw $t3,($t1)
beq $t3,$a0,2f
lw $t1,4($t1)
lw $t2,4($t2)
j 1b
2:
sw $a1,($t2)
j 4f
3:
addi $sp,$sp,-16
sw $zero,($sp)
sw $ra,12($sp)
lw $t0,($a2)
sw $a1,8($sp)
lw $a1,($t0)
sw $t0,4($sp)
jal cons
lw $t0,4($sp)
sw $v0,($t0)
lw $a0,8($sp)
lw $a1,4($t0)
jal cons
lw $t0,4($sp)
sw $v0,4($t0)
lw $ra,12($sp)
addi $sp,$sp,16
4: