-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathPeanoModel.v
1463 lines (1410 loc) · 51.8 KB
/
PeanoModel.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(** Prop-valued model of IsProof IsWeakPeanoAxiom, to show its consistency.
This both shows that IsProof is correctly implemented, and pushes the
incompleteness of Heyting arithmetic one step further : there exists a
Peano proposition that is neither provable, nor refutable.
This model looks like HAstandardModel, but uses double negations before
disjunctions and existentials, to make them classical. *)
Require Import Arith.Wf_nat.
Require Import PeanoNat.
Require Import Arith.Compare_dec.
Require Import EnumSeqNat.
Require Import Formulas.
Require Import Substitutions.
Require Import IsFreeForSubst.
Require Import PeanoAxioms.
Require Import Proofs.
Require Import HeytingModel.
(** Interpretation of Peano propositions as Prop *)
(* We use the Gödel-Gentzen double-negation translation, to model classical logic.
The atomic propositions x = y and x <= y do not need double negations, because
they are recursive.
We interpret all undefined relations by False, so that we will establish
that nothing can be proved about them. *)
Definition PAstandardModelRec (f : nat) (rec : nat -> (nat -> nat) -> Prop) (varValues : nat -> nat)
: Prop :=
match CoordNat f 0 with
| LnotHead => not (rec 1 varValues)
| LimpliesHead => rec 1 varValues -> rec 2 varValues
| LorHead => ~~(rec 1 varValues \/ rec 2 varValues)
| LandHead => rec 1 varValues /\ rec 2 varValues
| LforallHead => forall n:nat, rec 2 (setValue (CoordNat f 1) n varValues)
| LexistsHead => ~~exists n:nat, rec 2 (setValue (CoordNat f 1) n varValues)
| LrelHead => if Nat.eqb (LengthNat f) 4 then
match CoordNat f 1 with
| 0 => HAstandardModelTerm varValues (CoordNat f 2)
= HAstandardModelTerm varValues (CoordNat f 3)
| 1 => HAstandardModelTerm varValues (CoordNat f 2)
<= HAstandardModelTerm varValues (CoordNat f 3)
| _ => False
end
else False
| _ => False
end.
Definition PAstandardModel : nat -> (nat -> nat) -> Prop
:= TreeFoldNat PAstandardModelRec (fun _ => False).
(* Satisfaction of an arithmetical formula in the standard model.
For a closed proposition f, varValues does not matter and be replaced by
fun _ => 0. *)
Definition PAstandardModelSat (f : nat) : Prop :=
forall varValues, PAstandardModel f varValues.
Lemma PAstandardModel_step : forall f,
PAstandardModel f
= TreeFoldNatRec PAstandardModelRec (fun _ => False) f
(fun k _ => PAstandardModel k).
Proof.
intros.
unfold PAstandardModel, TreeFoldNat. rewrite Fix_eq.
reflexivity.
intros. unfold PAstandardModelRec, TreeFoldNatRec.
destruct (le_lt_dec (LengthNat x) 0). reflexivity.
destruct (CoordNat x 0). reflexivity.
destruct n. rewrite H. reflexivity.
destruct n. rewrite H,H. reflexivity.
destruct n. rewrite H,H. reflexivity.
destruct n. rewrite H,H. reflexivity.
destruct n. rewrite H. reflexivity.
destruct n. rewrite H. reflexivity.
destruct n. reflexivity. reflexivity.
Qed.
Lemma FactorNotNotExists : forall P Q : nat -> Prop,
(forall n, P n <-> Q n) -> (~~(exists n, P n) <-> ~~(exists n, Q n)).
Proof.
split.
- intros. intro abs. contradict H0; intro H0. contradict abs.
destruct H0. exists x. rewrite <- H. apply H0.
- intros. intro abs. contradict H0; intro H0. contradict abs.
destruct H0. exists x. rewrite H. apply H0.
Qed.
(* TODO merge with VarIndep, by requiring equality on the free variables only. *)
Lemma PAstandardModel_ext : forall f val1 val2,
(forall n:nat, val1 n = val2 n)
-> (PAstandardModel f val1 <-> PAstandardModel f val2).
Proof.
apply (Fix lt_wf (fun f => forall val1 val2,
(forall n:nat, val1 n = val2 n)
-> (PAstandardModel f val1 <-> PAstandardModel f val2))).
intro f. intros.
rewrite PAstandardModel_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat f) 0). reflexivity.
unfold PAstandardModelRec.
destruct (CoordNat f 0). reflexivity.
destruct n.
(* Lnot *)
rewrite H. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)). exact H0.
destruct n.
(* Limplies *)
rewrite (H _ (CoordLower _ _ (LengthPositive _ l)) val1 val2).
rewrite (H _ (CoordLower _ _ (LengthPositive _ l)) val1 val2).
reflexivity. exact H0. exact H0.
destruct n.
(* Lor *)
rewrite (H _ (CoordLower _ _ (LengthPositive _ l)) val1 val2).
rewrite (H _ (CoordLower _ _ (LengthPositive _ l)) val1 val2).
reflexivity. exact H0. exact H0.
destruct n.
(* Land *)
rewrite (H _ (CoordLower _ _ (LengthPositive _ l)) val1 val2).
rewrite (H _ (CoordLower _ _ (LengthPositive _ l)) val1 val2).
reflexivity. exact H0. exact H0.
destruct n.
(* Lforall *)
apply FactorForall. intro n.
rewrite (H _ (CoordLower _ _ (LengthPositive _ l))
_ (setValue (CoordNat f 1) n val2)).
reflexivity.
intro k. unfold setValue. destruct (Nat.eqb k (CoordNat f 1)).
reflexivity. apply H0.
destruct n.
(* Lexists *)
apply FactorNotNotExists. intro n.
rewrite (H _ (CoordLower _ _ (LengthPositive _ l))
_ (setValue (CoordNat f 1) n val2)).
reflexivity.
intro k. unfold setValue. destruct (Nat.eqb k (CoordNat f 1)).
reflexivity. apply H0.
(* Lop *)
destruct n.
rewrite (HAstandardModelTerm_ext _ val1 val2).
rewrite (HAstandardModelTerm_ext _ val1 val2). reflexivity.
exact H0. exact H0. reflexivity.
Qed.
Lemma PAstandardModel_not : forall varValues f,
PAstandardModel (Lnot f) varValues
= ~(PAstandardModel f varValues).
Proof.
intros. rewrite PAstandardModel_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat (Lnot f)) 0).
exfalso. rewrite LengthLnot in l. inversion l.
unfold PAstandardModelRec, Lnot; rewrite CoordConsHeadNat.
rewrite CoordConsTailNat.
rewrite CoordConsHeadNat.
reflexivity.
Qed.
Lemma PAstandardModel_or : forall varValues f g,
PAstandardModel (Lor f g) varValues
= ~~(PAstandardModel f varValues \/ PAstandardModel g varValues).
Proof.
intros. rewrite PAstandardModel_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat (Lor f g)) 0).
exfalso. rewrite LengthLor in l. inversion l.
unfold PAstandardModelRec, Lor; rewrite CoordConsHeadNat.
do 3 rewrite CoordConsTailNat.
do 2 rewrite CoordConsHeadNat.
reflexivity.
Qed.
Lemma PAstandardModel_and : forall varValues f g,
PAstandardModel (Land f g) varValues
= (PAstandardModel f varValues /\ PAstandardModel g varValues).
Proof.
intros. rewrite PAstandardModel_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat (Land f g)) 0).
exfalso. rewrite LengthLand in l. inversion l.
unfold PAstandardModelRec, Land; rewrite CoordConsHeadNat.
do 3 rewrite CoordConsTailNat.
do 2 rewrite CoordConsHeadNat.
reflexivity.
Qed.
Lemma PAstandardModel_implies : forall varValues f g,
PAstandardModel (Limplies f g) varValues
= (PAstandardModel f varValues -> PAstandardModel g varValues).
Proof.
intros. rewrite PAstandardModel_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat (Limplies f g)) 0).
exfalso. rewrite LengthLimplies in l. inversion l.
unfold PAstandardModelRec, Limplies; rewrite CoordConsHeadNat.
do 3 rewrite CoordConsTailNat.
do 2 rewrite CoordConsHeadNat.
reflexivity.
Qed.
Lemma PAstandardModel_equiv : forall varValues f g,
PAstandardModel (Lequiv f g) varValues
<-> (PAstandardModel f varValues <-> PAstandardModel g varValues).
Proof.
intros. unfold Lequiv.
rewrite PAstandardModel_and, PAstandardModel_implies, PAstandardModel_implies.
reflexivity.
Qed.
Lemma PAstandardModel_eq : forall varValues a b,
PAstandardModel (Leq a b) varValues
= (HAstandardModelTerm varValues a = HAstandardModelTerm varValues b).
Proof.
intros. rewrite PAstandardModel_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat (Leq a b)) 0).
unfold Leq in l. rewrite LengthLrel2 in l. inversion l.
unfold PAstandardModelRec, Leq, Lrel2, Lrel; rewrite CoordConsHeadNat.
do 4 rewrite LengthConsNat. simpl.
do 6 rewrite CoordConsTailNat.
do 3 rewrite CoordConsHeadNat.
reflexivity.
Qed.
Lemma PAstandardModel_le : forall varValues a b,
PAstandardModel (PAle a b) varValues
= (HAstandardModelTerm varValues a <= HAstandardModelTerm varValues b).
Proof.
intros. rewrite PAstandardModel_step.
unfold TreeFoldNatRec, PAle.
destruct (le_lt_dec (LengthNat (Lrel2 1 a b)) 0).
rewrite LengthLrel2 in l. inversion l.
unfold PAstandardModelRec, PAle, Lrel2, Lrel; rewrite CoordConsHeadNat.
do 4 rewrite LengthConsNat. simpl.
do 6 rewrite CoordConsTailNat.
do 3 rewrite CoordConsHeadNat.
reflexivity.
Qed.
Lemma PAstandardModel_rel : forall varValues r args,
PAstandardModel (Lrel r args) varValues
= (if LengthNat args =? 2
then
match r with
| 0 =>
HAstandardModelTerm varValues (CoordNat args 0) =
HAstandardModelTerm varValues (CoordNat args 1)
| 1 =>
HAstandardModelTerm varValues (CoordNat args 0) <=
HAstandardModelTerm varValues (CoordNat args 1)
| S (S _) => False
end
else False).
Proof.
intros. rewrite PAstandardModel_step.
unfold TreeFoldNatRec. rewrite LengthLrel. simpl.
unfold PAstandardModelRec.
unfold Lrel. rewrite CoordConsHeadNat.
rewrite LengthConsNat, LengthConsNat. simpl.
do 5 rewrite CoordConsTailNat.
rewrite CoordConsHeadNat.
reflexivity.
Qed.
Lemma PAstandardModel_forallHead : forall varValues f,
CoordNat f 0 = LforallHead
-> PAstandardModel f varValues
= (forall n:nat, PAstandardModel (CoordNat f 2) (setValue (CoordNat f 1) n varValues)).
Proof.
intros. rewrite PAstandardModel_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat f) 0).
exfalso. rewrite CoordNatAboveLength in H.
discriminate. exact l.
unfold PAstandardModelRec; rewrite H.
reflexivity.
Qed.
Lemma PAstandardModel_forall : forall varValues v f,
PAstandardModel (Lforall v f) varValues
= (forall n:nat, PAstandardModel f (setValue v n varValues)).
Proof.
intros.
rewrite PAstandardModel_forallHead.
rewrite CoordNat_forall_1, CoordNat_forall_2.
reflexivity.
unfold Lforall.
rewrite CoordConsHeadNat.
reflexivity.
Qed.
Lemma PAstandardModel_exists : forall varValues v f,
PAstandardModel (Lexists v f) varValues
= ~~(exists n:nat, PAstandardModel f (setValue v n varValues)).
Proof.
intros. rewrite PAstandardModel_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat (Lexists v f)) 0).
exfalso. rewrite LengthLexists in l. inversion l.
unfold PAstandardModelRec, Lexists; rewrite CoordConsHeadNat.
do 3 rewrite CoordConsTailNat.
do 2 rewrite CoordConsHeadNat.
reflexivity.
Qed.
(** Evaluations of substitutions by PAstandardModel *)
Lemma VarIndepTerm : forall t v (varValues : nat -> nat) y,
VarOccursInTerm v t = false
-> (HAstandardModelTerm (setValue v y varValues) t
= HAstandardModelTerm varValues t).
Proof.
apply (Fix lt_wf (fun t => forall v (varValues : nat -> nat) y,
VarOccursInTerm v t = false
-> (HAstandardModelTerm (setValue v y varValues) t
= HAstandardModelTerm varValues t))).
intros t IHt v varValues y H.
rewrite HAstandardModelTerm_step, HAstandardModelTerm_step.
unfold TreeFoldNatRec.
assert (VarOccursInTerm v t = false) by (exact H).
unfold VarOccursInTerm in H0.
apply Bool.negb_false_iff in H0.
rewrite SubstTerm_step in H0.
unfold TreeFoldNatRec in H0.
destruct (le_lt_dec (LengthNat t) 0).
reflexivity.
unfold HAstandardModelTermRec.
unfold SubstTermRec in H0.
apply Nat.eqb_eq in H0.
destruct (CoordNat t 0) eqn:headT. reflexivity.
do 7 (destruct n; [reflexivity|]).
destruct n.
(* Lop, go through each PAmodel's operation according to the length of t. *)
destruct (LengthNat t) eqn:lenT. reflexivity.
destruct n. reflexivity.
destruct n. reflexivity.
destruct n.
(* Successor *)
rewrite IHt. reflexivity.
rewrite <- lenT in l.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
apply Bool.negb_false_iff, Nat.eqb_eq in H.
rewrite SubstTerm_opHead in H. 2: exact headT.
apply (f_equal (fun a => CoordNat a 2)) in H.
rewrite CoordNat_op, CoordMapNat, CoordRangeNat in H. exact H.
rewrite lenT. apply Nat.le_refl.
rewrite LengthRangeNat. rewrite lenT. apply Nat.le_refl.
destruct n.
(* Addition and multiplication *)
2: reflexivity.
rewrite IHt, IHt. reflexivity.
rewrite <- lenT in l.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
apply Bool.negb_false_iff, Nat.eqb_eq in H.
rewrite SubstTerm_opHead in H. 2: exact headT.
apply (f_equal (fun a => CoordNat a 3)) in H.
rewrite CoordNat_op, CoordMapNat, CoordRangeNat in H. exact H.
rewrite lenT. apply Nat.le_refl.
rewrite LengthRangeNat. rewrite lenT. apply Nat.le_refl.
apply CoordLower, LengthPositive. rewrite lenT. auto.
apply Bool.negb_false_iff, Nat.eqb_eq.
apply Bool.negb_false_iff, Nat.eqb_eq in H.
rewrite SubstTerm_opHead in H. 2: exact headT.
apply (f_equal (fun a => CoordNat a 2)) in H.
rewrite CoordNat_op, CoordMapNat, CoordRangeNat in H. exact H.
rewrite lenT. apply le_n_S, le_0_n.
rewrite LengthRangeNat. rewrite lenT. apply le_n_S, le_0_n.
(* Lvar *)
destruct n. 2: reflexivity.
unfold setValue.
destruct (CoordNat t 1 =? v).
rewrite <- H0 in l. inversion l. reflexivity.
Qed.
Lemma VarIndep : forall f v (varValues : nat -> nat) y,
VarOccursFreeInFormula v f = false
-> (PAstandardModel f (setValue v y varValues)
<-> PAstandardModel f varValues).
Proof.
apply (Fix lt_wf (fun f => forall (v : nat) (varValues : nat -> nat) (y : nat),
VarOccursFreeInFormula v f = false ->
PAstandardModel f (setValue v y varValues) <-> PAstandardModel f varValues)).
intros f IHf v varValues y nooccur.
apply Bool.negb_false_iff, Nat.eqb_eq in nooccur.
rewrite PAstandardModel_step. unfold TreeFoldNatRec.
rewrite Subst_step in nooccur. unfold TreeFoldNatRec in nooccur.
destruct (le_lt_dec (LengthNat f) 0).
reflexivity.
unfold SubstRec in nooccur.
unfold PAstandardModelRec.
destruct (CoordNat f 0) eqn:headF.
(* Lnot *)
reflexivity. destruct n. rewrite IHf. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
rewrite <- nooccur at 2.
rewrite CoordNat_not_1. reflexivity.
destruct n.
(* Limplies *)
rewrite IHf,IHf. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
rewrite <- nooccur at 2.
rewrite CoordNat_implies_2. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
rewrite <- nooccur at 2.
rewrite CoordNat_implies_1. reflexivity.
destruct n.
(* Lor *)
rewrite IHf,IHf. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
rewrite <- nooccur at 2.
rewrite CoordNat_or_2. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
rewrite <- nooccur at 2.
rewrite CoordNat_or_1. reflexivity.
destruct n.
(* Land *)
rewrite IHf,IHf. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
rewrite <- nooccur at 2.
rewrite CoordNat_and_2. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
rewrite <- nooccur at 2.
rewrite CoordNat_and_1. reflexivity.
destruct n.
(* Lforall *)
apply FactorForall; intro n.
destruct (CoordNat f 1 =? v) eqn:des.
apply Nat.eqb_eq in des.
rewrite des.
rewrite (PAstandardModel_ext
_ _ _ (SetSetValueIdem varValues v _ _)).
reflexivity.
apply Nat.eqb_neq in des.
rewrite (PAstandardModel_ext
_ _ _ (SetSetValueCommute varValues _ _ _ _ des)).
rewrite IHf. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
rewrite <- nooccur at 2.
rewrite CoordNat_forall_2. reflexivity.
destruct n.
(* Lexists *)
apply FactorNotNotExists; intro n.
destruct (CoordNat f 1 =? v) eqn:des.
apply Nat.eqb_eq in des.
rewrite des.
rewrite (PAstandardModel_ext
_ _ _ (SetSetValueIdem varValues v _ _)).
reflexivity.
apply Nat.eqb_neq in des.
rewrite (PAstandardModel_ext
_ _ _ (SetSetValueCommute varValues _ _ _ _ des)).
rewrite IHf. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply Bool.negb_false_iff, Nat.eqb_eq.
rewrite <- nooccur at 2.
rewrite CoordNat_exists_2. reflexivity.
destruct n.
(* Lrel, 2 cases Leq and PAle *)
2: reflexivity.
destruct (LengthNat f) eqn:lenF. reflexivity.
destruct n. reflexivity.
destruct n. reflexivity.
destruct n. reflexivity.
destruct n. 2: reflexivity. simpl.
assert (LengthNat (TailNat (TailNat f)) = 2) as H.
{ rewrite LengthTailNat, LengthTailNat, lenF. reflexivity. }
rewrite VarIndepTerm, VarIndepTerm. reflexivity.
apply Bool.negb_false_iff, Nat.eqb_eq.
apply (f_equal (fun n => CoordNat n 3)) in nooccur.
rewrite CoordNat_rel, CoordMapNat, CoordTailNat, CoordTailNat in nooccur.
exact nooccur. rewrite LengthTailNat, LengthTailNat, lenF. auto.
apply Bool.negb_false_iff, Nat.eqb_eq.
apply (f_equal (fun n => CoordNat n 2)) in nooccur.
rewrite CoordNat_rel, CoordMapNat, CoordTailNat, CoordTailNat in nooccur.
exact nooccur. rewrite LengthTailNat, LengthTailNat, lenF.
apply le_n_S, le_0_n.
Qed.
Lemma PAstandardModel_SubstTerm : forall t u v varValues,
HAstandardModelTerm varValues (SubstTerm u v t)
= HAstandardModelTerm (setValue v (HAstandardModelTerm varValues u) varValues) t.
Proof.
apply (Fix lt_wf (fun t => forall u v varValues,
HAstandardModelTerm varValues (SubstTerm u v t)
= HAstandardModelTerm (setValue v (HAstandardModelTerm varValues u) varValues) t)).
intros t IHt u v varValues.
rewrite SubstTerm_step.
rewrite (HAstandardModelTerm_step _ t).
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat t) 0).
- reflexivity.
- pose proof (LengthPositive t l) as tpos.
unfold SubstTermRec. unfold HAstandardModelTermRec.
destruct (CoordNat t 0) eqn:headT.
reflexivity.
do 7 (destruct n; [reflexivity|]).
destruct n.
+ (* case Lop, i.e. PAzero, PAsucc, PAplus or PAmult *)
destruct (LengthNat t) eqn:lent.
exfalso; inversion l. clear l.
destruct n. simpl. rewrite MapNilNat.
apply HAstandardModelTerm_length2.
unfold Lop. rewrite CoordConsHeadNat. reflexivity.
rewrite LengthLop. reflexivity.
destruct n.
(* case PAzero *)
simpl. rewrite MapNilNat.
apply HAstandardModelTerm_length2.
unfold Lop. rewrite CoordConsHeadNat. reflexivity.
rewrite LengthLop. reflexivity.
destruct n.
(* case PAsucc *)
rewrite <- (IHt (CoordNat t 2) (CoordLower t 2 tpos)).
simpl. rewrite MapConsNat, MapNilNat.
rewrite HAstandardModelTerm_length3.
3: rewrite LengthLop, LengthConsNat; reflexivity.
2: unfold Lop; rewrite CoordConsHeadNat; reflexivity.
rewrite CoordNat_op, CoordConsHeadNat. reflexivity.
destruct n.
(* case PAplus or PAmult *)
simpl.
rewrite MapConsNat, MapConsNat, MapNilNat.
rewrite HAstandardModelTerm_length4.
rewrite CoordNat_op, CoordNat_op.
unfold Lop at 1. rewrite CoordConsTailNat, CoordConsHeadNat.
rewrite CoordConsHeadNat.
rewrite CoordConsTailNat, CoordConsHeadNat.
rewrite IHt, IHt. reflexivity.
exact (CoordLower t 3 tpos).
exact (CoordLower t 2 tpos).
unfold Lop. rewrite CoordConsHeadNat. reflexivity.
rewrite LengthLop, LengthConsNat, LengthConsNat. reflexivity.
(* case length too high *)
apply HAstandardModelTerm_length5.
rewrite <- headT.
unfold Lop. rewrite CoordConsHeadNat.
symmetry. exact headT.
rewrite LengthLop, LengthMapNat, LengthRangeNat.
do 5 apply le_n_S. apply le_0_n.
+ (* case Lvar *)
destruct n. 2: reflexivity. clear IHt.
unfold setValue.
destruct (CoordNat t 1 =? v) eqn:des.
reflexivity.
rewrite HAstandardModelTerm_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat t) 0).
exfalso. inversion l0. rewrite H0 in l.
exact (Nat.lt_irrefl 0 l).
unfold HAstandardModelTermRec. rewrite headT. reflexivity.
Qed.
Lemma PAstandardModel_Subst : forall prop u v (varValues : nat -> nat),
IsFreeForSubst u v prop = true
-> (PAstandardModel (Subst u v prop) varValues
<-> PAstandardModel prop (setValue v (HAstandardModelTerm varValues u) varValues)).
Proof.
apply (Fix lt_wf (fun prop => forall u v (varValues : nat -> nat),
IsFreeForSubst u v prop = true
-> (PAstandardModel (Subst u v prop) varValues
<-> PAstandardModel prop (setValue v (HAstandardModelTerm varValues u) varValues)))).
intros prop IHprop u v varValues free.
rewrite Subst_step.
unfold TreeFoldNatRec.
rewrite (PAstandardModel_step prop).
unfold TreeFoldNatRec.
rewrite IsFreeForSubst_step in free.
unfold TreeFoldNatRec in free.
destruct (le_lt_dec (LengthNat prop) 0). discriminate.
unfold IsFreeForSubstRec in free.
unfold PAstandardModelRec.
unfold SubstRec.
destruct (CoordNat prop 0) eqn:headProp. discriminate.
destruct n.
(* Lnot *)
rewrite PAstandardModel_not, IHprop. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
exact free.
destruct n.
(* Limplies *)
apply andb_prop in free.
rewrite PAstandardModel_implies.
rewrite IHprop, IHprop. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply free.
exact (CoordLower _ _ (LengthPositive _ l)).
apply free.
destruct n.
(* Lor *)
apply andb_prop in free.
rewrite PAstandardModel_or.
rewrite IHprop, IHprop. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply free.
exact (CoordLower _ _ (LengthPositive _ l)).
apply free.
destruct n.
(* Land *)
apply andb_prop in free.
rewrite PAstandardModel_and.
rewrite IHprop, IHprop. reflexivity.
exact (CoordLower _ _ (LengthPositive _ l)).
apply free.
exact (CoordLower _ _ (LengthPositive _ l)).
apply free.
destruct n.
(* Lforall : 3 cases, same var, no subst and recurse.
The first 2 cases could be merged. *)
apply Bool.orb_prop in free.
rewrite PAstandardModel_forall.
apply FactorForall. intro n.
destruct (CoordNat prop 1 =? v) eqn:eqvar.
apply Nat.eqb_eq in eqvar. subst v.
symmetry.
rewrite (PAstandardModel_ext _ _ (setValue (CoordNat prop 1) n varValues)).
reflexivity.
intro k. apply SetSetValueIdem.
destruct free as [nosubst | free].
clear IHprop.
apply Bool.negb_true_iff in nosubst.
rewrite VarOccursFreeInFormula_forallHead in nosubst.
2: exact headProp.
apply Bool.negb_false_iff, Nat.eqb_eq in nosubst.
rewrite eqvar in nosubst.
assert (VarOccursFreeInFormula v (CoordNat prop 2) = false) as nosubst2.
{ apply Bool.negb_false_iff.
rewrite <- nosubst at 2. rewrite CoordNat_forall_2.
apply Nat.eqb_refl. }
symmetry.
rewrite (PAstandardModel_ext _ _ (setValue v (HAstandardModelTerm varValues u) (setValue (CoordNat prop 1) n varValues))).
2: apply SetSetValueCommute.
rewrite VarIndep.
rewrite Subst_nosubst. reflexivity.
exact nosubst2. exact nosubst2.
intro abs. rewrite abs, Nat.eqb_refl in eqvar. discriminate.
apply andb_prop in free.
rewrite IHprop.
rewrite (PAstandardModel_ext _ _ (setValue (CoordNat prop 1) n
(setValue v (HAstandardModelTerm varValues u) varValues))).
reflexivity. intro k.
rewrite VarIndepTerm. apply SetSetValueCommute.
intro abs. rewrite <- abs, Nat.eqb_refl in eqvar. discriminate.
destruct free.
apply Bool.negb_true_iff in H0. exact H0.
exact (CoordLower _ _ (LengthPositive _ l)).
apply free.
destruct n.
(* Lexists : 3 cases, same var, no subst and recurse.
The first 2 cases could be merged. *)
apply Bool.orb_prop in free.
rewrite PAstandardModel_exists.
apply FactorNotNotExists. intro n.
destruct (CoordNat prop 1 =? v) eqn:eqvar.
apply Nat.eqb_eq in eqvar. subst v.
symmetry.
rewrite (PAstandardModel_ext _ _ (setValue (CoordNat prop 1) n varValues)).
reflexivity.
intro k. apply SetSetValueIdem.
destruct free as [nosubst | free].
clear IHprop.
apply Bool.negb_true_iff in nosubst.
rewrite VarOccursFreeInFormula_existsHead in nosubst.
2: exact headProp.
apply Bool.negb_false_iff, Nat.eqb_eq in nosubst.
rewrite eqvar in nosubst.
assert (VarOccursFreeInFormula v (CoordNat prop 2) = false) as nosubst2.
{ apply Bool.negb_false_iff.
rewrite <- nosubst at 2. rewrite CoordNat_exists_2.
apply Nat.eqb_refl. }
symmetry.
rewrite (PAstandardModel_ext _ _ (setValue v (HAstandardModelTerm varValues u) (setValue (CoordNat prop 1) n varValues))).
2: apply SetSetValueCommute.
rewrite VarIndep. rewrite Subst_nosubst. reflexivity.
exact nosubst2. exact nosubst2.
intro abs. rewrite abs, Nat.eqb_refl in eqvar. discriminate.
apply andb_prop in free.
rewrite IHprop.
rewrite (PAstandardModel_ext _ _ (setValue (CoordNat prop 1) n
(setValue v (HAstandardModelTerm varValues u) varValues))).
reflexivity. intro k.
rewrite VarIndepTerm. apply SetSetValueCommute.
intro abs. rewrite <- abs, Nat.eqb_refl in eqvar. discriminate.
destruct free.
apply Bool.negb_true_iff in H0. exact H0.
exact (CoordLower _ _ (LengthPositive _ l)).
apply free.
destruct n.
(* Lrel *)
2: reflexivity.
rewrite PAstandardModel_rel, LengthMapNat.
rewrite LengthTailNat, LengthTailNat.
destruct (LengthNat prop) eqn:lenProp. reflexivity.
destruct n. reflexivity.
destruct n. reflexivity.
destruct n. reflexivity.
destruct n. 2: reflexivity. simpl (pred (pred 4)).
rewrite Nat.eqb_refl, Nat.eqb_refl.
rewrite CoordMapNat, CoordMapNat.
rewrite PAstandardModel_SubstTerm, PAstandardModel_SubstTerm.
rewrite CoordTailNat, CoordTailNat.
rewrite CoordTailNat, CoordTailNat.
reflexivity.
rewrite LengthTailNat, LengthTailNat, lenProp.
apply Nat.le_refl. auto.
rewrite LengthTailNat, LengthTailNat, lenProp. simpl. auto.
Qed.
(** Satisfaction of propositional logic in the standard model. *)
(* This is both an internal and external property of the standard model.
Internally the model satisfies ~~A->A, and externally it suffices to prove
~~PAstandardmodel prop varValues to prove PAstandardmodel prop varValues. *)
Lemma PAstandardModelNotNot : forall (prop : nat) (varValues : nat -> nat),
~~PAstandardModel prop varValues
-> PAstandardModel prop varValues.
Proof.
apply (Fix lt_wf (fun prop => forall (varValues : nat -> nat),
~ ~ PAstandardModel prop varValues -> PAstandardModel prop varValues)).
intros prop IHprop varValues.
rewrite PAstandardModel_step.
unfold TreeFoldNatRec.
destruct (le_lt_dec (LengthNat prop) 0).
intro abs. contradict abs. intro abs. contradiction.
unfold PAstandardModelRec.
destruct (CoordNat prop 0).
intro abs. contradict abs. intro abs. contradiction.
destruct n.
(* Lnot *)
intros notnotprop H. contradict notnotprop; intro notnotprop. contradiction.
destruct n.
(* Limplies *)
intros notnotprop H.
apply IHprop.
exact (CoordLower _ _ (LengthPositive _ l)).
intro abs. contradict notnotprop; intro notnotprop.
contradict abs. apply notnotprop, H.
destruct n.
(* Lor *)
intros notnotprop abs.
contradict notnotprop; intro notnotprop.
contradict notnotprop; intro notnotprop.
contradict abs. exact notnotprop.
destruct n.
(* Land *)
intro notnotprop. split. apply IHprop.
exact (CoordLower _ _ (LengthPositive _ l)).
intro abs. contradict notnotprop; intro notnotprop.
contradict abs. apply notnotprop.
apply IHprop.
exact (CoordLower _ _ (LengthPositive _ l)).
intro abs. contradict notnotprop; intro notnotprop.
contradict abs. apply notnotprop.
destruct n.
(* Lforall *)
intros notnotprop n.
apply IHprop.
exact (CoordLower _ _ (LengthPositive _ l)).
intro abs. contradict notnotprop; intro notnotprop.
contradict abs. apply notnotprop.
destruct n.
(* Lexists *)
intros notnotprop abs.
contradict notnotprop; intro notnotprop.
revert abs. exact notnotprop.
destruct n.
(* Lrel *)
clear IHprop. intro notnotprop.
destruct (LengthNat prop =? 4).
destruct (CoordNat prop 1).
destruct (Nat.eq_dec (HAstandardModelTerm varValues (CoordNat prop 2))
(HAstandardModelTerm varValues (CoordNat prop 3))).
exact e. contradiction.
destruct n.
destruct (le_dec (HAstandardModelTerm varValues (CoordNat prop 2))
(HAstandardModelTerm varValues (CoordNat prop 3))).
exact l0. contradiction.
contradict notnotprop. intro abs. contradiction.
contradict notnotprop; intro notnotprop. contradiction.
intro abs. contradict abs. intro abs. contradiction.
Qed.
(* ~~X1 -> X1, the only classical axiom *)
Lemma Ax4Satisfied : forall (prop : nat),
IsPropAx4 prop = true -> PAstandardModelSat prop.
Proof.
intros prop H varValues.
do 4 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H3. rewrite H3, PAstandardModel_implies.
apply Nat.eqb_eq in H2. rewrite H2, PAstandardModel_not.
apply Nat.eqb_eq in H1. rewrite H1, PAstandardModel_not.
apply Nat.eqb_eq in H0. rewrite H0.
apply PAstandardModelNotNot.
Qed.
(* This internal property of the model does not extend to a constructive
external excluded middle
PAstandardModel prop varValues \/ ~PAstandardModel prop varValues *)
Lemma ExcludedMiddleSatisfied : forall prop,
PAstandardModelSat (Lor prop (Lnot prop)).
Proof.
intros prop varValues. rewrite PAstandardModel_or.
intro abs. assert (~~PAstandardModel prop varValues).
intro H. contradict abs. right. rewrite PAstandardModel_not. exact H.
contradict H; intro H. contradict abs. left. exact H.
Qed.
(* (X1 -> (X2 -> X3)) -> ((X1 -> X2) -> (X1 -> X3)) *)
Lemma Ax2Satisfied : forall (prop : nat),
IsPropAx2 prop = true -> PAstandardModelSat prop.
Proof.
intros prop H varValues.
do 10 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H9.
rewrite H9, PAstandardModel_implies. intro X1X2X3.
apply Nat.eqb_eq in H6.
rewrite H6, PAstandardModel_implies. intro X1X2.
apply Nat.eqb_eq in H4.
rewrite H4, PAstandardModel_implies. intro X1.
apply Nat.eqb_eq in H5.
rewrite H5, PAstandardModel_implies in X1X2.
apply Nat.eqb_eq in H2.
rewrite <- H2 in X1.
apply Nat.eqb_eq in H3.
rewrite <- H3 in X1X2.
specialize (X1X2 X1).
apply Nat.eqb_eq in H8.
rewrite H8, PAstandardModel_implies in X1X2X3.
specialize (X1X2X3 X1).
apply Nat.eqb_eq in H7.
rewrite H7, PAstandardModel_implies in X1X2X3.
apply Nat.eqb_eq in H1.
rewrite H1 in X1X2X3.
specialize (X1X2X3 X1X2).
apply Nat.eqb_eq in H0.
rewrite <- H0. exact X1X2X3.
Qed.
(* X1 -> (~X1 -> X2) *)
Lemma Ax5Satisfied : forall (prop : nat),
IsPropAx5 prop = true -> PAstandardModelSat prop.
Proof.
intros prop H varValues.
do 4 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H3.
apply Nat.eqb_eq in H2.
apply Nat.eqb_eq in H0.
apply Nat.eqb_eq in H1.
rewrite H3, PAstandardModel_implies.
intro X1.
rewrite H2, PAstandardModel_implies.
intro notX1.
rewrite H1, PAstandardModel_not, <- H0 in notX1.
contradiction.
Qed.
(* X1 -> (X2 -> (X1 /\ X2)) *)
Lemma Ax6Satisfied : forall (prop : nat),
IsPropAx6 prop = true -> PAstandardModelSat prop.
Proof.
intros prop H varValues.
do 5 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H0.
apply Nat.eqb_eq in H1.
apply Nat.eqb_eq in H2.
apply Nat.eqb_eq in H3.
apply Nat.eqb_eq in H4.
rewrite H4, PAstandardModel_implies.
intro X1.
rewrite H3, PAstandardModel_implies.
intro X2.
rewrite H2, PAstandardModel_and.
split.
rewrite <- H1. exact X1.
rewrite <- H0. exact X2.
Qed.
(* (X1 -> X3) -> ((X2 -> X3) -> ((X1 \/ X2) -> X3)) *)
Lemma Ax11Satisfied : forall (prop : nat),
IsPropAx11 prop = true -> PAstandardModelSat prop.
Proof.
intros prop H varValues.
do 10 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H9.
apply Nat.eqb_eq in H8.
apply Nat.eqb_eq in H7.
apply Nat.eqb_eq in H6.
apply Nat.eqb_eq in H5.
apply Nat.eqb_eq in H4.
apply Nat.eqb_eq in H3.
apply Nat.eqb_eq in H2.
apply Nat.eqb_eq in H1.
apply Nat.eqb_eq in H0.
rewrite H9, PAstandardModel_implies. intro X1implX3.
rewrite H7, PAstandardModel_implies. intro X2implX3.
rewrite H5, PAstandardModel_implies. intro X1orX2.
rewrite H4, PAstandardModel_or in X1orX2.
apply PAstandardModelNotNot.
intro abs; contradict X1orX2; intro X1orX2; contradict abs.
rewrite <- H0.
destruct X1orX2 as [X1 | X2].
rewrite H8, PAstandardModel_implies in X1implX3.
apply X1implX3. rewrite <- H3 in X1. exact X1.
rewrite H6, PAstandardModel_implies, <- H1 in X2implX3.
apply X2implX3. rewrite <- H2 in X2. exact X2.
Qed.
Lemma PropositionalAxiomsSatisfied : forall prop,
IsPropositionalAxiom prop = true
-> PAstandardModelSat prop.
Proof.
intros prop H varValues.
apply Bool.orb_prop in H; destruct H.
apply Bool.orb_prop in H; destruct H.
apply Bool.orb_prop in H; destruct H.
apply Bool.orb_prop in H; destruct H.
apply Bool.orb_prop in H; destruct H.
apply Bool.orb_prop in H; destruct H.
apply Bool.orb_prop in H; destruct H.
apply Bool.orb_prop in H; destruct H.
apply Bool.orb_prop in H; destruct H.
- (* X1 -> (X2 -> X1) *)
do 3 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H2.
rewrite H2, PAstandardModel_implies. intro X1.
apply Nat.eqb_eq in H1.
rewrite H1, PAstandardModel_implies.
intro J.
apply Nat.eqb_eq in H0.
rewrite H0 in X1. exact X1.
- apply Ax2Satisfied, H.
- (* (X1 -> X2) -> ((X1 -> ~X2) -> ~X1) *)
do 9 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H8.
apply Nat.eqb_eq in H7.
apply Nat.eqb_eq in H6.
apply Nat.eqb_eq in H5.
apply Nat.eqb_eq in H4.
apply Nat.eqb_eq in H3.
apply Nat.eqb_eq in H1.
apply Nat.eqb_eq in H2.
apply Nat.eqb_eq in H0.
rewrite H8, PAstandardModel_implies; intro X1implX2.
rewrite H6, PAstandardModel_implies; intro X1implnotX2.
rewrite H4, PAstandardModel_not; intro X1.
rewrite H5, PAstandardModel_implies in X1implnotX2.
rewrite H7, PAstandardModel_implies in X1implX2.
rewrite <- H1 in X1. specialize (X1implX2 X1).
rewrite <- H2 in X1implnotX2. specialize (X1implnotX2 X1).
rewrite H3, PAstandardModel_not, <- H0 in X1implnotX2.
contradiction.
- apply Ax5Satisfied, H.
- apply Ax6Satisfied, H.
- (* (X1 /\ X2) -> X1 *)
do 3 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H2.
rewrite H2, PAstandardModel_implies.
intro X1andX2.
apply Nat.eqb_eq in H1.
rewrite H1, PAstandardModel_and in X1andX2.
apply Nat.eqb_eq in H0.
rewrite <- H0. apply X1andX2.
- (* (X1 /\ X2) -> X2 *)
do 3 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H2.
rewrite H2, PAstandardModel_implies.
intro X1andX2.
apply Nat.eqb_eq in H1.
rewrite H1, PAstandardModel_and in X1andX2.
apply Nat.eqb_eq in H0.
rewrite <- H0. apply X1andX2.
- (* X1 -> (X1 \/ X2) *)
do 3 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H2.
rewrite H2, PAstandardModel_implies.
intro X1.
apply Nat.eqb_eq in H1.
rewrite H1, PAstandardModel_or.
intro abs; contradict abs.
left.
apply Nat.eqb_eq in H0.
rewrite <- H0. exact X1.
- (* X2 -> (X1 \/ X2) *)
do 3 (apply andb_prop in H; destruct H).
apply Nat.eqb_eq in H2.
rewrite H2, PAstandardModel_implies.
intro X2.
apply Nat.eqb_eq in H1.