build.gradle

apply plugin: 'me.champeau.jmh'

dependencies {
    api 'com.netflix.archaius:archaius-core:0.4.1'
    api 'io.reactivex:rxjava:1.2.0'
    implementation 'org.slf4j:slf4j-api:1.7.0'
    api 'org.hdrhistogram:HdrHistogram:2.1.9'
    testImplementation 'junit:junit-dep:4.10'
    testImplementation project(':hystrix-junit')
}


javadoc {
    // the exclude isn't working, nor is there a subPackages options as docs suggest there should be
    // we do not want the com.netflix.hystrix.util package include
    exclude '**/util/**'

    options {
        doclet = "org.benjchristensen.doclet.DocletExclude"
        docletpath = [rootProject.file('./gradle/doclet-exclude.jar')]
        stylesheetFile = rootProject.file('./gradle/javadocStyleSheet.css')
        windowTitle = "Hystrix Javadoc ${project.version}"
    }
    options.addStringOption('top').value = '<a href="https://github.com/Netflix/Hystrix"><img width="92" height="79" border="0" align="left" src="http://netflix.github.com/Hystrix/images/hystrix-logo-small.png"></a><h2 class="title" style="padding-top:40px">Hystrix: Latency and Fault Tolerance for Distributed Systems</h2>'
}

jmh {
    fork = 10
    iterations = 3
    jmhVersion = '1.15'
    profilers = ['gc']
    threads = 8
    warmup = '1s'
    warmupBatchSize = 1
    warmupIterations = 5
}