-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathpanel-tnut.scad
569 lines (495 loc) · 20.6 KB
/
panel-tnut.scad
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
//
// PANEL-TNUT
// by ISC 2021-09
//
// TNutCageProfile( ... ) - create profile
// TNutCage_M( profile, connectedPanelThickness ) - draw 2D bolt/nut capture slots
// TNutCage_F( profile, allowance ) - draw 2D hole for perpendicular panel
// TNutCages( targetWidth, count, profile, connectedPanelThickness, holeAllowance ) - repeated bolt/nut capture slots
//
include <KVTree.scad>
//
// DEMO
//
// run me !!!
//$vpr=[0,0,0]; TNutCage_Demo_2D();
//TNutCage_Demo();
//TNutCage_Assembly_Demo();
module TNutCage_Demo_2D() {
include <nuts-bolts.scad>
include <orientation.scad>
$fn=20;
panelThickness = 3;
boltDiameter = 3; nutDiameter = 5;
boltLength = 20; nutThickness = 3;
nutEdgeGap = 8;
// SIMPLE PROFILE
profile1 = TNutCageProfile(
connectedPanelThickness = panelThickness,
boltDiameter = boltDiameter, nutDiameter = nutDiameter,
boltLength = boltLength, nutThickness = nutThickness,
nutEdgeGap = nutEdgeGap
);
// PROFILE WITH ALLOWANCES
profile2 = TNutCageProfile(
connectedPanelThickness = panelThickness,
boltDiameter = boltDiameter, nutDiameter = nutDiameter,
boltLength = boltLength, nutThickness = nutThickness,
nutEdgeGap = nutEdgeGap,
// allowance from physical sizes...
boltDiameterAllowance = 2,
boltLengthAllowance = 1,
nutDiameterAllowance = 2,
nutThicknessAllowance = 2
);
// *** BASIC ***
translate([0,0,0]) {
malePanel(20)
/* ▶ */ TNutCage_M( profile1 );
femalePanel(20,panelThickness,boltDiameter)
/* ▶ */ TNutCage_F( profile1 );
translate([0,panelThickness,0]) dummyBolt();
translate([0,-nutEdgeGap,0]) dummyNut();
}
// *** OVERRIDE CONNECTED PANEL THICKNESS ***
translate([30,0,0]) {
THK=5;
malePanel(20)
/* ▶ */ TNutCage_M( profile1, connectedPanelThickness=THK );
femalePanel(20,THK,boltDiameter)
/* ▶ */ TNutCage_F( profile1 );
translate([0,THK,0]) dummyBolt();
translate([0,-nutEdgeGap,0]) dummyNut();
}
// *** WITH BOLT/NUT ALLOWANCES ***
translate([60,0,0]) {
malePanel(20)
/* ▶ */ TNutCage_M( profile2 );
femalePanel(20,panelThickness,boltDiameter)
/* ▶ */ TNutCage_F( profile2, allowance=2 );
translate([0,panelThickness,0]) dummyBolt();
translate([0,-nutEdgeGap,0]) dummyNut();
}
// *** MULTIPLE SLOTS ***
translate([130,0,0]) {
malePanel(100)
/* ▶ */ TNutCage( 100, 3, profile2 );
femalePanel(100,panelThickness,boltDiameter)
/* ▶ */ TNutCage( 100, -3, profile2 );
patternRepeater(100,3) {
translate([0,panelThickness,0]) dummyBolt();
translate([0,-nutEdgeGap,0]) dummyNut();
color("red") translate([0,20,0]) circle(d=boltDiameter);
}
}
module malePanel(width) {
difference() {
translate([0,-10,0]) square([width,20],center=true);
children();
}
}
module femalePanel(width,thickness,boltDiameter) {
color("SteelBlue") translate([0,thickness/2,0])
square([width,thickness],center=true);
translate([0,20,0]) {
color("SteelBlue") difference() {
square([width,10],center=true);
children();
}
color("red") circle(d=boltDiameter);
}
}
module dummyBolt() {
color("red") {
translate([0,-boltLength/2,1]) square([boltDiameter,boltLength],center=true);
translate([-boltDiameter,0,1]) square([boltDiameter*2,3]);
}
}
module dummyNut() {
color("green") translate([0,-nutThickness/2,2])
square([nutDiameter,nutThickness],center=true);
}
}
module TNutCage_Demo() {
include <nuts-bolts.scad>
include <orientation.scad>
$fn=20;
panelThickness = 3;
// SIMPLE PROFILE
profile1 = TNutCageProfile(
connectedPanelThickness = panelThickness,
boltLength = 15, nutDiameter = 5,
boltDiameter = 3, nutThickness = 3,
nutEdgeGap = 5
);
// PROFILE FROM PHYSICAL BOLT/NUT
boltProfile = BoltProfile(
shaftDiameter = 3,
length = 20,
headDiameter = 5,
headThickness = 3 );
nutProfile = NutProfile(
boltDiameter = 3,
nutDiameter = 5,
thickness = 3 );
profile2 = TNutCageProfile(
connectedPanelThickness = panelThickness,
boltProfile = boltProfile,
nutProfile = nutProfile,
nutEdgeGap = 8, // panel edge to captured nut
boltDiameterAllowance = 1, // allowance from physical sizes...
boltLengthAllowance = 0.5,
nutDiameterAllowance = 1,
nutThicknessAllowance = 1
);
kvEchoAligned(profile2);
// ...possibly extract from another module
edgeGap =kvGet(profile2,"nut.edgeGap");
nutThickness=kvGet(profile2,"nut.thickness");
// *** BASIC ***
translate([0,0,0]) {
panelMale()
/* ▶ */ TNutCage_M( profile1 );
translate( [0,panelThickness/2,0] ) rotate( [90,0,0] ) panelFemale(panelThickness)
/* ▶ */ TNutCage_F( profile1 );
}
// *** WITH BOLTS/NUTS ***
// - see "nuts-bolts.scad"
translate([50,0,0]) //rotate([0,0,180])
{
rotate([-90,0,0]) color( "lightgray" ) {
translate( [0,0,panelThickness] )
Bolt(boltProfile);
translate([0,0,-edgeGap-nutThickness]) rotate([0,0,30])
Nut(nutProfile);
}
panelMale()
/* ▶ */ TNutCage_M( profile2 );
translate([0,panelThickness/2,0]) rotate([90,0,0]) panelFemale(panelThickness)
/* ▶ */ TNutCage_F( profile2 );
}
// *** ORIENTATION HELPERS ***
// - see "orientation.scad"
translate([100,0,0]) {
THK=8;
OFFront(THK) color( "lightgray" ) {
OBottom(THK)
Bolt(boltProfile);
OBottom(THK,edgeGap+THK+nutThickness) rotate([0,0,30])
Nut(nutProfile);
}
panelMale()
/* ▶ */ TNutCage_M( profile2, connectedPanelThickness=THK );
OFront(THK) panelFemale(THK)
/* ▶ */ TNutCage_F( profile2, allowance=2 );
}
module panelMale() {
linear_extrude(panelThickness,center=true)
difference() {
translate([0,-10,0]) square([20,20],center=true); // panel top at origin
children();
}
}
module panelFemale(thickness) {
color("SteelBlue",0.5)
linear_extrude(thickness,center=true)
difference() {
square([20,20],center=true);
children();
}
}
}
module TNutCage_Assembly_Demo() {
include <nuts-bolts.scad>
include <positioning.scad>
include <orientation.scad>
$fn=20;
W = 80; // width
D = 50; // depth
H = 100; // height
T = 3; // panel thickness
S1 = 10; // shelf1 position (from bottom)
S2 = 50; // shelf2 position (from bottom)
SF1 = S1+T/2; // shelf1 front panel height
SF2 = H-S2+T/2; // shelf2 front panel height
EXT = 5; // extension to place bolts
boltProfile = BoltProfile(
shaftDiameter = 1,
length = 10,
headDiameter = 3,
headThickness = 1 );
nutProfile = NutProfile(
boltDiameter = 1,
nutDiameter = 3,
thickness = 1 );
profile = TNutCageProfile(
connectedPanelThickness = T,
boltProfile = boltProfile,
nutProfile = nutProfile,
nutEdgeGap = 4, // panel edge to captured nut
boltDiameterAllowance = 1, // allowance from physical sizes...
boltLengthAllowance = 0.5,
nutDiameterAllowance = 1,
nutThicknessAllowance = 1
);
// ...possibly extract from another module
edgeGap =kvGet(profile,"nut.edgeGap");
nutThickness=kvGet(profile,"nut.thickness");
assembly();
translate([120,0,0])
rotate([0,0,180])
assembly();
showBolts=true;
module assembly() {
CubeExtents(W,D,H);
// shelves
color("LightGrey") OBottom (0,H/2-S1) solid() shelfBottom();
color("LightGrey") OBottom( 0,H/2-S2) solid() shelfBottom();
if (showBolts) OFBottom(0,H/2-S1) shelfBottomBolts();
if (showBolts) OBottom (0,H/2-S2) shelfBottomBolts();
// walls
OLeft (T,W/2) solid() walls();
ORight (T,W/2) solid() rotate([0,180,0]) walls();
if (showBolts) OLeft (T,W/2) wallBolts();
if (showBolts) OFRight(T,W/2) mirror([0,0,1]) wallBolts();
// shelves front panel
color("gray") OFront(T,D/2,0,-H/2+SF1/2) solid() frontPanel1();
color("gray") OFront(T,D/2,0, H/2-SF2/2) solid() frontPanel2();
if (showBolts) OFront(T,D/2,0,-H/2+SF1/2) frontPanel1Bolts();
if (showBolts) OFront(T,D/2,0, H/2-SF2/2) frontPanel2Bolts();
// back panel
color("DarkGray") OBack(T,D/2) solid() back();
if (showBolts) OBack(T,D/2) backBolts();
}
module solid() linear_extrude(T,center=true) children();
module boltNut() {
color("SandyBrown") {
translate([0,0,T/2]) Bolt(boltProfile);
translate([0,0,-T/2-nutThickness-edgeGap]) Nut(nutProfile);
}
}
// *** WALLS ***
module walls() {
left = -T;
right = +EXT;
effD = D+left+right;
punch() {
MRight((-left+right)/2)
square([effD,H],center=true);
union() {
MUp(S1) PBottom(H) TNutCage(D,-2,profile); // holes for shelf bottom
MUp(S2) PBottom(H) TNutCage(D,-2,profile);
MLeft(T/2) PRight(D) TNutCage(H,-3,profile); // back panel
// shelves front panel
MDown(H/2-SF1/2) MLeft(left) PLeft(D) TNutCage(SF1,1,profile);
MUp (H/2-SF2/2) MLeft(left) PLeft(D) TNutCage(SF2,2,profile);
}
}
}
module wallBolts() {
// those with negative (-) count in walls() are holes, plug with bolts
// while testing, show only:
// - wallBolts();
// - solid() walls();
MUp(S1) PBottom(H) patternRepeater(D,2) boltNut();
MUp(S2) PBottom(H) patternRepeater(D,2) boltNut();
MLeft(T/2) PRight(D) patternRepeater(H,3) boltNut();
}
// *** BACK ***
module back() {
effW=W-2*T;
punch() {
square([effW,H],center=true);
union() {
PLeft(effW) TNutCage(H, 3,profile); // walls
PRight(effW) TNutCage(H, 3,profile);
MUp(S1) PBottom(H) TNutCage(W,-2,profile); // shelves bottom
MUp(S2) PBottom(H) TNutCage(W,-2,profile);
}
}
}
module backBolts() {
MUp(S1) PBottom(H) patternRepeater(W,2) boltNut();
MUp(S2) PBottom(H) patternRepeater(W,2) boltNut();
}
// *** SHELVES BOTTOM ***
module shelfBottom() {
top = -T;
bottom = +EXT;
effD = D+top+bottom;
effW = W-2*T;
punch() {
MDown((-top+bottom)/2)
square([effW,effD],center=true);
union() {
MRight(T) PLeft(W) TNutCage(D, 2,profile); // walls
MLeft(T) PRight(W) TNutCage(D, 2,profile);
MUp(bottom-T) PBottom(D) TNutCage(W,-2,profile); // front
MDown(-top) PTop(D) TNutCage(W, 2,profile); // back
}
}
}
module shelfBottomBolts() {
bottom = +EXT;
MUp(bottom-T) PBottom(D) patternRepeater(W,2) boltNut();
}
// *** SHELVES FRONT ***
module frontPanel1() {
effW =W+EXT*2;
top =-T;
effSF1=SF1+top;
punch() {
MDown(-top/2)
square([effW,effSF1],center=true);
union() {
MRight(T/2) PLeft(W) TNutCage(SF1,-1,profile); // walls
MLeft (T/2) PRight(W) TNutCage(SF1,-1,profile);
MDown(-top/2) PTop(effSF1) TNutCage(W , 2,profile); // front
}
}
}
module frontPanel1Bolts() {
top =-T;
MRight(T/2) PLeft( W) patternRepeater(SF1,1) boltNut();
MLeft (T/2) PLeft(-W) patternRepeater(SF1,1) boltNut();
}
module frontPanel2() {
effW =W+EXT*2;
bottom=-T;
effSF2=SF2+bottom;
punch() {
MUp(-bottom/2)
square([effW,effSF2],center=true);
union() {
MRight(T/2) PLeft(W) TNutCage(SF2,-2,profile); // walls
MLeft (T/2) PRight(W) TNutCage(SF2,-2,profile);
MUp(-bottom/2) PBottom(effSF2) TNutCage(W , 2,profile); // front
}
}
}
module frontPanel2Bolts() {
bottom=-T;
MRight(T/2) PLeft( W) patternRepeater(SF2,2) boltNut();
MLeft (T/2) PLeft(-W) patternRepeater(SF2,2) boltNut();
}
// to diagnose a part while designing,
// set debug to true and generate the part. ex:
// debug=true;
// walls();
//debug=true;
debug=false;
module punch() {
if (debug) {
color("green",0.5)
difference() {
children(0); children(1);
}
children(1);
} else {
difference() {
children(0); children(1);
}
}
}
}
//
// T-NUT CAGE
//
// TOP VIEW (P1)
// | +---+ - - - - - - - - - -
// | | | ^
// +---------+ +----+ --- |
// | boltDiameter nutDiameter
// +---------+ +----+ --- |
// | | | v
// | +---+ - - - - - - - - - -
//
// |<- gap ->| |<-- nutThickness
//
// |<-- boltArea -->| boltArea = boltLength - panelThickness
//
// SIDE VIEW:
// |P2|
// | | P1 connected to P2
// | | P1 (male) will capture the bolt with a nut
// ##| +---@------- P2 (female) has a hole for the bolt
// ##|##|###@## P1 ### - bolt
// ##| +---@------- @@@ - nut
// | |
// +--+
//
// technically, P1 is more female :)
function TNutCageProfile(
connectedPanelThickness, // thickness of panel to be connected (P2 in diagram)
boltDiameter, // bolt info
boltLength,
nutDiameter, // nut info
nutThickness,
nutEdgeGap, // distance from panel edge to nut capture slot
boltProfile, // specify instead of boltLength, boltDiameter
nutProfile, // specify instead of boltDiameter, nutDiameter, nutThickness
boltDiameterAllowance = 0,
boltLengthAllowance = 0,
nutDiameterAllowance = 0,
nutThicknessAllowance = 0
) = let(
eBoltLength = SELECT( boltLength, kvSearchLax( boltProfile, "length" ) ),
eBoltDiameter = SELECT( boltDiameter, kvSearchLax( boltProfile, "diameter" ), kvSearchLax( nutProfile, "boltDiameter" ) ),
eNutDiameter = SELECT( nutDiameter, kvSearchLax( nutProfile, "nutDiameter" ) ),
eNutThickness = SELECT( nutThickness, kvSearchLax( nutProfile, "thickness" ) ),
e1=ErrorIf(eBoltLength ==undef, "boltLength or boltProfile required" ),
e2=ErrorIf(eBoltDiameter==undef, "boltDiameter, boltProfile or nutProfile required" ),
e3=ErrorIf(eNutDiameter ==undef, "nutDiameter or nutProfile required" ),
e4=ErrorIf(eNutThickness==undef, "nutThickness or nutProfile required" ),
e5=ErrorIf(nutEdgeGap ==undef, "nutEdgeGap required" )
) KVTree([
// keep data to cut the holes, not bolt/nut information
"connectedPanelThickness", connectedPanelThickness,
"bolt", KVTree([ "effDiameter", eBoltDiameter+boltDiameterAllowance, "effLength", eBoltLength+boltLengthAllowance ]),
"nut", KVTree([ "effDiameter", eNutDiameter+nutDiameterAllowance,
"thickness", eNutThickness, "thicknessAllowance", nutThicknessAllowance,
"edgeGap", nutEdgeGap ])
]);
module TNutCage(targetWidth,count,profile,connectedPanelThickness,holeAllowance=0) {
// connectedPanelThickness - for TNutCage()
// holeAllowance - for TNutCagePanelHole()
if (count>0)
patternRepeater(targetWidth,count)
TNutCage_M(profile,connectedPanelThickness);
else
patternRepeater(targetWidth,-count)
TNutCage_F(profile,holeAllowance);
}
module TNutCage_M(profile,connectedPanelThickness) {
overlap=1; // extra on top for clean punch
ePanelThickness=SELECT(connectedPanelThickness,kvGet(profile,"connectedPanelThickness"));
bolt =kvGet(profile,"bolt");
eBoltDiameter=kvGet(bolt,"effDiameter");
eBoltLength =kvGet(bolt,"effLength" )-ePanelThickness;
nut =kvGet(profile,"nut");
nutDiameter =kvGet(nut,"effDiameter" );
nutThickness=kvGet(nut,"thickness" );
nTa =kvGet(nut,"thicknessAllowance");
nutEdgeGap =kvGet(nut,"edgeGap" );
translate( [0,-eBoltLength/2+overlap/2,0] )
square( [eBoltDiameter,eBoltLength+overlap], center=true );
translate( [0,-nutEdgeGap-nutThickness/2,0] )
square( [nutDiameter,nutThickness+nTa], center=true );
}
module TNutCage_F(profile,allowance=0) {
boltDiameter=kvGet(profile,"bolt.effDiameter");
circle( d=boltDiameter+allowance );
}
//
// SPACE EVENLY
//
module patternRepeater(length,count) {
// repeat children count times along length
// spaced evenly
gap=length/(count+1);
translate( [-length/2,0,0] )
for (i = [1:count]) {
translate( [i*gap,0,0] )
children();
}
}