-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathlinear-rail.scad
362 lines (331 loc) · 12.4 KB
/
linear-rail.scad
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
//
// LINEAR RAILS
// by ISC 2021-09
//
// rough visual representation only
// accurate measurement/holes for product design
//
// not sure if SHF and SK are official names
// based it off what the seller calls them
//
// SHF:
// profile = LinearRailHolderSHFProfile( ... ) - create profile
// LinearRailHolderSHF( profile ) - draw 3D
// LinearRailHolderSHFPanelHole( profile ) - draw 2D panel holes
//
// SK:
// profile = LinearRailHolderSKProfile( ... ) - create profile
// LinearRailHolderSK( profile ) - draw 3D
// LinearRailHolderSKPanelHole( profile ) - draw 2D panel holes
//
include <KVTree.scad>
include <utility.scad>
//
// DEMO
//
// run me!!!
LinearRailHolderSHF_Demo();
translate([100,0,0]) LinearRailHolderSK_Demo();
module LinearRailHolderSHF_Demo() {
profile = LinearRailHolderSHFProfile(
model = "SHF8",
shaftDiameter = 8,
boltDistance = 34,
width = 34+5+2+2, // overall width
centerRingDiameter = 8+5,
baseHeight = 14, // shaft center to base bottom
baseWidth = 20,
slit = 1
);
profileAuto = LinearRailHolderSHFProfile(
model = "SHF8-auto",
shaftDiameter = 8,
boltDistance = 34
);
LinearRailHolderSHF( profile );
kvEchoAligned( profile );
translate([0,40,0])
LinearRailHolderSHF( profileAuto );
translate([0,-40,-3])
linear_extrude(3)
difference() {
square([70,25],center=true);
LinearRailHolderSHFPanelHole( profile );
}
}
module LinearRailHolderSK_Demo() {
profileAuto = LinearRailHolderSKProfile(
model = "SK8-auto",
shaftDiameter = 8,
shaftHeight = 20,
boltDistance = 32
);
profile = LinearRailHolderSKProfile(
model = "SK8",
shaftDiameter = 8,
shaftHeight = 20, // floor to shaft center
boltDiameter = 5,
boltDistance = 32,
width = 18,
height = 33, // overall height
thickness = 15,
baseWidth = 41,
baseHeight = 5,
slit = 1
);
LinearRailHolderSKProfile( profile );
kvEchoAligned( profile );
translate([0,40,0])
LinearRailHolderSKProfile( profileAuto );
translate([0,-40,-3])
linear_extrude(3)
difference() {
square([70,25],center=true);
LinearRailHolderSKPanelHole( profile );
}
shaftHeight = kvGet(profile, "shaft.height" );
color("green")
translate([0,20,shaftHeight])
rotate([90,0,0])
cylinder(100,d=8,center=true);
}
//
// HOLDER SHF
//
function LinearRailHolderSHFProfile(
model = "",
shaftDiameter,
boltDiameter = 5,
boltDistance, // bolt to bolt distance
thickness = 10,
width = undef, // overall width
centerRingDiameter = undef, // diameter of ring around shaft
baseHeight = undef, // shaft center to base bottom
baseWidth = undef,
slit = 1 // clamp slit width on base
) = let (
e1=ErrorIf( shaftDiameter==undef, "shaft diameter missing" ),
e2=ErrorIf( boltDistance ==undef, "bolt distance missing" ),
eWidth = SELECT( width , boltDistance+boltDiameter*1.5 ),
eRD = SELECT( centerRingDiameter, shaftDiameter*1.6 ),
eBaseHeight = SELECT( baseHeight, shaftDiameter*2 ),
eBaseWidth = SELECT( baseWidth , shaftDiameter*2.5 )
) KVTree([
"type" , "linear rail holder SHF",
"model" , model,
"shaftDiameter", shaftDiameter,
"bolt" , KVTree([ "diameter", boltDiameter, "distance", boltDistance ]),
"body" , KVTree([ "width", eWidth, "ringDiameter", eRD, "thickness", thickness ]),
"base" , KVTree([ "width", eBaseWidth, "height", eBaseHeight, "slit", slit ])
]);
module LinearRailHolderSHF( profile ) {
t = kvSearch(profile,"type");
e1=ErrorIf( t!="linear rail holder SHF", "LinearRailHolderSHF(): invalid profile" );
go();
module go() {
shaftDiameter = kvGet(profile, "shaftDiameter" );
boltDiameter = kvGet(profile, "bolt.diameter" );
boltToBolt = kvGet(profile, "bolt.distance" );
body = kvGet(profile,"body");
width = kvGet(body, "width" );
ringDiameter = kvGet(body, "ringDiameter" );
thickness = kvGet(body, "thickness" );
base = kvGet(profile,"base");
baseWidth = kvGet(base, "width" );
baseHeight = kvGet(base, "height" );
slitWidth = kvGet(base, "slit" );
sideDiameters = width - boltToBolt;
linear_extrude(thickness)
difference() {
union() {
hull() {
translate([-boltToBolt/2,0,0])
circle(d=sideDiameters);
translate([boltToBolt/2,0,0])
circle(d=sideDiameters);
circle(d=ringDiameter);
}
translate([0,-baseHeight/2])
square([baseWidth,baseHeight],center=true);
}
union() {
translate([-boltToBolt/2,0,0])
circle(d=boltDiameter);
translate([boltToBolt/2,0,0])
circle(d=boltDiameter);
circle(d=shaftDiameter);
translate([0,-baseHeight/2])
square([slitWidth,baseHeight],center=true);
}
}
}
}
module LinearRailHolderSHFPanelHole( profile, omitCenterHole=true, enlargeShaft=1, enlargeBolt=1 ) {
t = kvSearch(profile,"type");
e1=ErrorIf( t!="linear rail holder SHF", "LinearRailHolderSHFPanelHole(): invalid profile" );
go();
module go() {
shaftDiameter = kvGet(profile, "shaftDiameter" );
boltDiameter = kvGet(profile, "bolt.diameter" );
boltToBolt = kvGet(profile, "bolt.distance" );
b2b2 = boltToBolt/2;
if ( !omitCenterHole )
circle( d=shaftDiameter+enlargeShaft );
translate( [ b2b2,0,0] ) circle( d=boltDiameter+enlargeBolt );
translate( [-b2b2,0,0] ) circle( d=boltDiameter+enlargeBolt );
}
}
/*
boltDistance=34;
boltDiameter=5;
shaftDiameter=8;
centerDiameter=18;
sideDiameter=9;
baseHeight=14;
baseWidth=20;
slitWidth=1;
difference() {
union() {
hull() {
translate([-boltDistance/2,0,0])
circle(d=sideDiameter);
translate([boltDistance/2,0,0])
circle(d=sideDiameter);
circle(d=centerDiameter);
}
translate([0,-baseHeight/2])
square([baseWidth,baseHeight],center=true);
}
union() {
translate([-boltDistance/2,0,0])
circle(d=boltDiameter);
translate([boltDistance/2,0,0])
circle(d=boltDiameter);
circle(d=shaftDiameter);
translate([0,-baseHeight/2])
square([slitWidth,baseHeight],center=true);
}
}
*/
//
// HOLDER SK
//
function LinearRailHolderSKProfile(
model = "",
shaftDiameter,
shaftHeight, // floor to shaft center
boltDiameter = 5,
boltDistance, // bolt to bolt distance
thickness = 10,
width = undef, // width of shaft holder
height = undef, // overall height
baseWidth = undef,
baseHeight = 8,
slit = 1
) = let (
e1=ErrorIf( shaftDiameter==undef, "shaft diameter missing" ),
e2=ErrorIf( shaftHeight ==undef, "shaft height missing" ),
e3=ErrorIf( boltDistance ==undef, "bolt distance missing" ),
eWidth = SELECT( width , shaftDiameter*2 ),
eHeight = SELECT( height , shaftHeight+boltDiameter*2 ),
eBaseWidth = SELECT( baseWidth , boltDistance+boltDiameter*2 ),
eBaseHeight = SELECT( baseHeight, shaftDiameter*2 )
) KVTree([
"type" , "linear rail holder SK",
"model" , model,
"shaft" , KVTree([ "diameter", shaftDiameter, "height", shaftHeight ]),
"bolt" , KVTree([ "diameter", boltDiameter, "distance", boltDistance ]),
"body" , KVTree([ "width", eWidth, "height", eHeight, "thickness", thickness, "slit", slit ]),
"base" , KVTree([ "width", eBaseWidth, "height", eBaseHeight ])
]);
module LinearRailHolderSKProfile( profile ) {
t = kvSearch(profile,"type");
e1=ErrorIf( t!="linear rail holder SK", "LinearRailHolderSKProfile(): invalid profile" );
go();
module go() {
shaftDiameter = kvGet(profile, "shaft.diameter" );
shaftHeight = kvGet(profile, "shaft.height" );
boltDiameter = kvGet(profile, "bolt.diameter" );
boltToBolt = kvGet(profile, "bolt.distance" );
body = kvGet(profile,"body");
width = kvGet(body, "width" );
height = kvGet(body, "height" );
thickness = kvGet(body, "thickness" );
slitWidth = kvGet(body, "slit" );
base = kvGet(profile,"base");
baseWidth = kvGet(base, "width" );
baseHeight = kvGet(base, "height" );
rotate([90,0,0])
linear_extrude(thickness,center=true)
difference()
{
translate([-width/2,0,0])
square([width,height]);
union() {
translate([0,shaftHeight,0])
circle(d=shaftDiameter);
slitHeight=height-shaftHeight;
translate([-slitWidth/2,height-slitHeight,0])
square([slitWidth,slitHeight+1]);
}
}
linear_extrude(baseHeight)
difference() {
square([baseWidth,thickness],center=true);
union() {
translate([-boltToBolt/2,0,0])
circle(d=boltDiameter);
translate([boltToBolt/2,0,0])
circle(d=boltDiameter);
}
}
}
}
module LinearRailHolderSKPanelHole( profile, enlargeBolt=1 ) {
t = kvSearch(profile,"type");
e1=ErrorIf( t!="linear rail holder SK", "LinearRailHolderSKPanelHole(): invalid profile" );
go();
module go() {
boltDiameter = kvGet(profile, "bolt.diameter" );
boltToBolt = kvGet(profile, "bolt.distance" );
b2b2 = boltToBolt/2;
translate( [ b2b2,0,0] ) circle( d=boltDiameter+enlargeBolt );
translate( [-b2b2,0,0] ) circle( d=boltDiameter+enlargeBolt );
}
}
/*
boltDistance=32;
boltDiameter=5;
shaftDiameter=8;
shaftHeight=20;
width=18;
height=33;
thickness=15;
baseWidth=41;
baseHeight=5;
slit=1;
rotate([90,0,0])
linear_extrude(thickness,center=true)
difference()
{
translate([-width/2,0,0])
square([width,height]);
union() {
translate([0,shaftHeight,0])
circle(d=shaftDiameter);
slitHeight=height-shaftHeight;
translate([-slit/2,height-slitHeight,0])
square([slit,slitHeight+1]);
}
}
linear_extrude(baseHeight)
difference() {
square([baseWidth,thickness],center=true);
union() {
translate([-boltDistance/2,0,0])
circle(d=boltDiameter);
translate([boltDistance/2,0,0])
circle(d=boltDiameter);
}
}
*/