build.gradle

plugins {
	id 'fabric-loom' version '1.6-SNAPSHOT' apply false
	id 'glue' version '0.0.5'
	id 'maven-publish'
}

glue {
	// subproject names in the order they'll be glued
	targets = ['legacy', 'legacy2', 'legacy3', 'main', 'glue']
	// output path defaults to build/libs/archives_base_name-mod_version.jar
	outputName = "${project.archives_base_name}-${project.mod_version}-universal"
}

allprojects {
	version = rootProject.mod_version
	group = rootProject.maven_group
}

subprojects {
	apply plugin: 'fabric-loom'

	repositories {
		maven { url = 'https://maven.shedaniel.me/' }
		maven { url = 'https://maven.terraformersmc.com/' }
	}

	dependencies {
		minecraft "com.mojang:minecraft:${project.minecraft_version}"
		mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
		modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	}

	base {
		archivesName = project.archives_base_name
	}

	processResources {
		inputs.property 'version', project.version

		filesMatching('fabric.mod.json') {
			expand 'version': project.version
		}
	}

	jar {
		from('../LICENSE') {
			rename { "${it}_${project.base.archivesName.get()}"}
		}
	}
}

publishing {
	publications {
		create("mavenJava", MavenPublication) {
			artifactId = project.archives_base_name
			artifact "build/libs/${glue.outputName}.jar" // TODO from glue
		}
	}
}

tasks.publish.dependsOn('glue')