Day 8 part 1

Author: timocp

src/adventofcode2024.gleam

@@ -14,6 +14,7 @@ import day4
 import day5
 import day6
 import day7
+import day8
 
 pub fn main() {
   case argv.load().arguments {
@@ -22,7 +23,7 @@ pub fn main() {
         Ok(d) -> run(d)
         Error(_) -> io.println("Invalid day: " <> arg)
       }
-    _ -> list.range(1, 7) |> list.each(fn(d) { run(d) })
+    _ -> list.range(1, 8) |> list.each(fn(d) { run(d) })
   }
 }
 
@@ -37,6 +38,7 @@ fn run(d: Int) -> Nil {
       5 -> day5.part1(input) |> int.to_string
       6 -> day6.part1(input) |> int.to_string
       7 -> day7.part1(input) |> int.to_string
+      8 -> day8.part1(input) |> int.to_string
       _ -> "(not implemented)"
     }
   })

src/day8.gleam

@@ -0,0 +1,80 @@
+import gleam/dict.{type Dict}
+import gleam/list
+import gleam/result
+import gleam/string
+import grid.{type Pos}
+import parse
+
+pub fn part1(input: String) -> Int {
+  let #(antennas, width, height) = parse_input(input)
+
+  antennas
+  |> dict.keys
+  |> list.flat_map(fn(label) { antinodes_for(antennas, label, width, height) })
+  |> list.unique
+  |> list.length
+}
+
+fn antinodes_for(
+  antennas: Dict(String, List(Pos)),
+  label: String,
+  width: Int,
+  height: Int,
+) -> List(Pos) {
+  antennas
+  |> dict.get(label)
+  |> result.unwrap([])
+  |> list.combination_pairs
+  |> list.flat_map(fn(pair) {
+    [individual_antinode(pair.0, pair.1), individual_antinode(pair.1, pair.0)]
+  })
+  |> list.filter(fn(pos) {
+    pos.0 >= 0 && pos.0 < width && pos.1 >= 0 && pos.1 < height
+  })
+}
+
+fn individual_antinode(a: Pos, b: Pos) -> Pos {
+  let dx = a.0 - b.0
+  let dy = a.1 - b.1
+  #(a.0 + dx, a.1 + dy)
+}
+
+fn parse_input(input: String) -> #(Dict(String, List(Pos)), Int, Int) {
+  let lines = parse.lines(input)
+
+  let pos_to_char =
+    lines
+    |> list.index_map(fn(line, y) {
+      line
+      |> string.to_graphemes
+      |> list.index_map(fn(char, x) { #(#(x, y), char) })
+      |> list.filter(fn(poschar) { poschar.1 != "." })
+    })
+    |> list.flatten
+    |> dict.from_list
+
+  let width = lines |> list.first |> result.unwrap("") |> string.length
+  let height = lines |> list.length
+
+  #(
+    pos_to_char
+      |> dict.values
+      |> list.unique
+      |> list.map(fn(char) {
+        #(
+          char,
+          pos_to_char
+            |> dict.to_list
+            |> list.filter_map(fn(poschar) {
+              case poschar.1 == char {
+                True -> Ok(poschar.0)
+                False -> Error(Nil)
+              }
+            }),
+        )
+      })
+      |> dict.from_list,
+    width,
+    height,
+  )
+}

test/day8_test.gleam

@@ -0,0 +1,26 @@
+import gleeunit
+import gleeunit/should
+
+import day8
+
+pub fn main() {
+  gleeunit.main()
+}
+
+const example1 = "............
+........0...
+.....0......
+.......0....
+....0.......
+......A.....
+............
+............
+........A...
+.........A..
+............
+............
+"
+
+pub fn part1_test() {
+  day8.part1(example1) |> should.equal(14)
+}